xfce-base/thunar-volman: Bump to 4.19.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/thunar-volman/Manifest

@@ -1,2 +1,3 @@
 DIST thunar-volman-4.18.0.tar.bz2 510289 BLAKE2B 6da7042d85fbdb57b811d1a08c1bdc0b0449b0c37013a37a8a19f15901135cea544f469c68de7880ca10110c9418426ecd0747fd00725077b6e171ec4a0cccf9 SHA512 29681ede6274e999377e2aae2b157ed355d9e471416db2d4beb4432f84c60008f8c5008c87392c20da51d58fc3bd8f097d6f21764903baf1a301fb00e6166420
 DIST thunar-volman-4.19.0.tar.bz2 637733 BLAKE2B ae04dba36943db6ff213d92b22993133dde32fc4ee6cdba457060b35b53eea41e32583a3f4f8c1d070bac2fc462477270f783579beba71c24eb4a6b021f910c1 SHA512 611f32d33c0de2f36fc09f3119168445ffb0cb43cb73c0be9d032e03ab82dcd80dbd20dd7be60ac01f6805eb5db3378724c9ea87bdbb1e5109bf2a4192c79488
+DIST thunar-volman-4.19.1.tar.bz2 637465 BLAKE2B e237c64bd9c4e457e0ecf60ef0ae8fe800662cc668e48afebc80cdfd89170ed8fcce503ea13ae62ed1ebb75b1f59ed10ccd6247b07906f41f2b31a18247c15ae SHA512 3db9db667d3f18bd7c49d3b51a2deddfa61e96c4858caf8fb144833b71740967a8614966e97b3fc13feb63b4db35f9df209a80ce0d59a765e7ccb5a549aaf3b7

xfce-base/thunar-volman/thunar-volman-4.19.1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Daemon that enforces volume-related policies"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/thunar/thunar-volman
+	https://gitlab.xfce.org/xfce/thunar-volman/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+# CC for tvm-burn-cd.svg
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="libnotify"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	dev-libs/libgudev:=
+	>=x11-libs/gtk+-3.24.0:3
+	>=xfce-base/exo-0.10.0:=
+	>=xfce-base/libxfce4ui-4.16.0:=
+	>=xfce-base/libxfce4util-4.12.0:=
+	>=xfce-base/xfconf-4.12.0:=
+	libnotify? ( >=x11-libs/libnotify-0.7.0 )
+"
+RDEPEND="
+	${DEPEND}
+	virtual/udev
+	>=xfce-base/thunar-1.6[udisks]
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable libnotify notifications)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}