xfce-base/xfdesktop: Bump to 4.19.7

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfdesktop/Manifest

@@ -1,2 +1,3 @@
 DIST xfdesktop-4.18.1.tar.bz2 2133258 BLAKE2B 3d4f54b64a6adc5f52bf6b48862b1fbf9b9608113035fdce89a2cb08a674f773f42edc0e1d05a27e89de7df71f7d53f400b794a2a79888cf51570c3ab060db8b SHA512 cafb1e274bbabf1704a6452532fc79657af26eaf92a58374f87a70f31c35fbf213319c6658b3d18bfca2d555b69e07e46949407d1f80e5a37f48e76bbde9dc3e
 DIST xfdesktop-4.19.6.tar.bz2 1939350 BLAKE2B c9ed866cf4b8c149a359e4dcc34d21bcf8dff77828f7a6112c9184b1ed85791f6ed0092287c76d42c76cc7f8b75a5cdca986c9ea87334a1bc63cf1fc825d024d SHA512 fbbf04da174921e1772a3ffd7be57eeb8fe5d8c2161687b7f41d162848c39c3158231f7829fcc5525ad66e4a803b48deb8cb462f49036bed2d718299411e9f4c
+DIST xfdesktop-4.19.7.tar.bz2 1959548 BLAKE2B 1235e9d56f078ed0f2f36108fd6bf72de2efccaf8cdb15fdc64d7050becc9a09a03f9570c6dd45f8c67e46358dbe53a3224be47dec804a4edac9c02615f27831 SHA512 58dcfe4528783be325e19b8c3462747ab65764c7239140c14e66149238f1c068a823e24cbce265106211e6710c006b8299d1fc4d3399eb27903d15027c77e44b

xfce-base/xfdesktop/xfdesktop-4.19.7.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfdesktop/start
+	https://gitlab.xfce.org/xfce/xfdesktop/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+# CC for /usr/share/backgrounds, see backgrounds/README.md
+LICENSE="GPL-2+ CC-BY-SA-4.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="libnotify +thunar wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	>=x11-libs/cairo-1.16
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/garcon-0.6:=
+	>=xfce-base/libxfce4ui-4.18.0:=
+	>=xfce-base/libxfce4util-4.13:=
+	>=xfce-base/libxfce4windowing-4.19.8:=[X?]
+	>=xfce-base/xfconf-4.19.3:=
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	thunar? (
+		>=dev-libs/libyaml-0.2.5:=
+		>=xfce-base/thunar-4.17.10:=
+	)
+	wayland? ( >=gui-libs/gtk-layer-shell-0.7.0 )
+	X? ( >=x11-libs/libX11-1.6.7 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+		$(use_enable thunar file-icons)
+		$(use_enable thunar thunarx)
+		$(use_enable libnotify notifications)
+		# these aren't run via make check, they are only for manual use
+		--disable-tests
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}