net-p2p/ktorrent: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2020-12-12 18:57:35 +01:00
parent 2d539b6b15
commit fb1f967a4d
2 changed files with 103 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST ktorrent-20.12.0.tar.xz 2140524 BLAKE2B bfcdb8aa872dd4f974334bef2cfd794fc667dc08c270fcf0fae369e1ce6a899ad57105e2bdfa307d749b15aab928c8aa5ebac3fff17ccfa512aba39e92822f75 SHA512 bdfa0a67756169625668b2b062c9e4b980127923f7ce45ce7b47201bba9a6278c88f7a51be93055bcea0d21afeabc0203210171d996749c98e1f0662e26ff76d
DIST ktorrent-5.2.0.tar.xz 2056012 BLAKE2B c59cb34675b9c4e023b6c22f795bf146d64acaea069efa1f1663888a0ada6f7c8328a15bdc2fc453e31a9f451c6b0203dfdfd02098cc52f5d828b87c23d857b5 SHA512 141976612cfe6bf4bd06e96842d7bc51ced7a3ab8e13c25446a00c031054698f851fbb1a31f3425dda5a428408bb1ceb51a4a420eaf2e79193b17a0cc7d7a387
+102
View File
@@ -0,0 +1,102 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="optional"
ECM_TEST="optional"
KDE_RELEASE_SERVICE="true"
KFMIN=5.74.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.1
VIRTUALX_REQUIRED="test"
inherit ecm kde.org
DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
HOMEPAGE="https://apps.kde.org/en/ktorrent"
LICENSE="GPL-2"
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +kross +logviewer +magnetgenerator
+mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
BDEPEND="sys-devel/gettext"
COMMON_DEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=net-libs/libktorrent-${PVCUT}:5
infowidget? ( dev-libs/geoip )
kross? (
>=kde-frameworks/karchive-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kross-${KFMIN}:5
)
mediaplayer? (
>=media-libs/phonon-4.11.0
>=media-libs/taglib-1.5
)
rss? (
>=dev-qt/qtwebengine-${QTMIN}:5
>=kde-frameworks/syndication-${KFMIN}:5
)
shutdown? ( kde-plasma/libkworkspace:5 )
stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
"
DEPEND="${COMMON_DEPEND}
dev-libs/boost
"
RDEPEND="${COMMON_DEPEND}
ipfilter? (
app-arch/bzip2
app-arch/unzip
kde-apps/kio-extras:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
)
"
src_configure() {
local mycmakeargs=(
-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
-DWITH_SYSTEM_GEOIP=$(usex infowidget)
-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
-DENABLE_SCRIPTING_PLUGIN=$(usex kross)
-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
$(cmake_use_find_package rss KF5Syndication)
-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
-DENABLE_STATS_PLUGIN=$(usex stats)
-DENABLE_UPNP_PLUGIN=$(usex upnp)
-DENABLE_SEARCH_PLUGIN=$(usex webengine)
-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
)
# add back when ported
# -DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
ecm_src_configure
}