net-libs/libktorrent: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-libs/libktorrent/Manifest

@@ -1 +1,2 @@
 DIST libktorrent-2.2.0.tar.xz 357364 BLAKE2B 66a91fc32dc11a680d22755468513896c9cea1cbaef8664c84633860b78efba85e5c9e47684fdaaf7fb6f03f624268f9158ee2b8c6fc3d14b0e70339c1f6903e SHA512 2edcb3a230f4fa3a55a6b774c819f4964fe8f2f5447b723ba81cdb0c187dc0268b6e78566d710fa364abe2cc40cd618d1874ecb1637e872fbad0ea8c340abc1a
+DIST libktorrent-20.12.0.tar.xz 604492 BLAKE2B 0a423d9b289806160109acb44d604af0e475aefc847a4c1ad1ac904fc776058db5eb7beb79ff2e573b9aff010ad57e30adeecd2c0c67afe89ba85aeb12eb215a SHA512 3c782b31ab4ed18660b331bcb0e28b61209cd070354d4dfd0c27152090e6baa1d63ad8faf5ffe41f4ec59d0ede98580317a16ee01a47ddf6d1e773ee61f4fcd0

net-libs/libktorrent/libktorrent-20.12.0.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="network"
+KDE_RELEASE_SERVICE="true"
+KFMIN=5.74.0
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="BitTorrent library based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/en/ktorrent https://userbase.kde.org/KTorrent"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND="sys-devel/gettext"
+COMMON_DEPEND="
+	>=app-crypt/qca-2.3.0:2
+	>=dev-libs/gmp-6.0.0a:0=
+	dev-libs/libgcrypt:0=
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+"
+RDEPEND="${COMMON_DEPEND}
+	!dev-libs/botan[gmp(-)]
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
+	sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
+		CMakeLists.txt || die
+	sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
+		KF5TorrentConfig.cmake.in || die
+}
+
+src_test() {
+	# failing network tests
+	local myctestargs=(
+		-E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
+	)
+
+	ecm_src_test
+}