sci-libs/gloo: add 2023.12.03

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

sci-libs/gloo/Manifest

@@ -1 +1,2 @@
 DIST gloo-2023.07.19.tar.gz 260264 BLAKE2B b787794a6b5e791da5f8693ad9a522c8caa5410316d64ad3a2c23ae744ca9f0b45ac6a6f60572049d3e5825a2e29833ff887fc39f6fe6a6efef61d848c225318 SHA512 e84e8a69a8548a8bfcb6044b960fca3204eb358c50fa79f3053779f2a61703d5219ef428f4ba057ed08e6ec437aadb7f8e67565f03f3510e0bf94c6f793af8d9
+DIST gloo-2023.12.03.tar.gz 259857 BLAKE2B b56cbbb0986b70ed327a8d019f140099c5d1d725576120089cd5e640dc42daa6c6bb67de877d540fd2160f5b8d89cf54af7c11a1b81039e62e4de97daa4f63d6 SHA512 597679dd96394e7d0009be34ef9bd6f8446d22e2faa006c0853e055caf0d6d821c7532ff867b4d924197e92ab53c4c7ee9b74f897d6c5a469ee797c11ce0d28d

sci-libs/gloo/gloo-2023.12.03.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake cuda
+
+CommitId=5354032ea08eadd7fc4456477f7f7c6308818509
+
+DESCRIPTION="library of floating-point neural network inference operators"
+HOMEPAGE="https://github.com/facebookincubator/gloo/"
+SRC_URI="https://github.com/facebookincubator/${PN}/archive/${CommitId}.tar.gz
+	-> ${P}.tar.gz"
+
+S="${WORKDIR}"/${PN}-${CommitId}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cuda libuv mpi redis ssl test"
+
+RDEPEND="
+	cuda? ( dev-util/nvidia-cuda-toolkit:= )
+	libuv? ( dev-libs/libuv )
+	mpi? ( virtual/mpi )
+	redis? (
+		dev-db/redis
+		dev-libs/hiredis
+	)
+	ssl? ( dev-libs/openssl:= )
+"
+DEPEND="${RDEPEND}
+"
+
+BDEPEND="test? ( dev-cpp/gtest )"
+RESTRICT="test" # For some test the network is needed
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2022.05.18-gentoo.patch
+	"${FILESDIR}"/${PN}-2023.01.17-cuda.patch
+	"${FILESDIR}"/${PN}-2023.01.17-ssl3.patch
+)
+
+src_prepare() {
+	eapply_user
+	cmake_src_prepare
+	use cuda && cuda_add_sandbox
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TEST=$(usex test ON OFF)
+		-DUSE_CUDA=$(usex cuda ON OFF)
+		-DGLOO_USE_CUDA_TOOLKIT=$(usex cuda ON OFF)
+		-DUSE_LIBUV=$(usex libuv ON OFF)
+		-DUSE_MPI=$(usex mpi ON OFF)
+		-DUSE_REDIS=$(usex redis ON OFF)
+		-DUSE_TCP_OPENSSL_LINK=$(usex ssl ON OFF)
+	)
+	if use cuda; then
+		addpredict "/proc/self/task"
+
+		mycmakeargs+=(
+			-DCMAKE_CUDA_FLAGS="$(cuda_gccdir -f | tr -d \")"
+		)
+	fi
+	cmake_src_configure
+}