dev-libs/FBGEMM: add 2023.12.04

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-libs/FBGEMM/FBGEMM-2023.12.04.ebuild

@@ -0,0 +1,79 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit python-any-r1 flag-o-matic cmake
+
+CommitId=dbc3157bf256f1339b3fa1fef2be89ac4078be0e
+
+DESCRIPTION="Facebook GEneral Matrix Multiplication"
+HOMEPAGE="https://github.com/pytorch/FBGEMM"
+SRC_URI="https://github.com/pytorch/${PN}/archive/${CommitId}.tar.gz
+	-> ${P}.tar.gz"
+
+S="${WORKDIR}"/${PN}-${CommitId}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+
+DEPEND="
+	>=dev-libs/asmjit-2022.07.02
+	dev-libs/cpuinfo
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	test? ( dev-cpp/gtest )
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+			dev-python/breathe[${PYTHON_USEDEP}]
+		')
+	)
+	${PYTHON_DEPS}
+"
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	if use doc; then
+		python_has_version \
+			"dev-python/sphinx[${PYTHON_USEDEP}]" \
+			"dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]" \
+			"dev-python/breathe[${PYTHON_USEDEP}]"
+	fi
+}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2023.11.02-gentoo.patch
+)
+
+src_prepare() {
+	# Bug #855668
+	filter-lto
+
+	rm test/RowWiseSparseAdagradFusedTest.cc || die
+	rm test/SparseAdagradTest.cc || die
+	sed -i \
+		-e "/-Werror/d" \
+		CMakeLists.txt \
+		|| die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFBGEMM_LIBRARY_TYPE=shared
+		-DFBGEMM_BUILD_BENCHMARKS=OFF
+		-DFBGEMM_BUILD_DOCS=$(usex doc ON OFF)
+		-DFBGEMM_BUILD_TESTS=$(usex test ON OFF)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	OMP_STACKSIZE=512k cmake_src_test
+}

dev-libs/FBGEMM/Manifest

@@ -1,2 +1,3 @@
 DIST FBGEMM-2023.11.02.tar.gz 895265 BLAKE2B 0f884147a86881159485680f1cb0c7b7e65bba5a98e62c38534041264f920e08a268e348e3d82ba3d246226a10f592d86dc37bce0cfa42c72dad478041a6c807 SHA512 030f27a120586240c5f80026bd033cf6fedbe1ae12a667308d33d6321f2334021d474a3625795d1f34734336b688b19c09134e10d5cc8dec86e84485de298584
 DIST FBGEMM-2023.12.01.tar.gz 1004090 BLAKE2B dc19ebee06bccb888e5d03606168c7439ce8c96303a697056edd22d3a3a6ff4f4f3ddf5371d50aa774890ca1ad66d665f5e54976dc1b8da841759a3f4d64c4d7 SHA512 ab37964326d2cbbcbf0f2c722675d1f059407fc3185275d37f2e04f3e516fe0733ac1fb35351fc7e7c308e9c0da40811d3657a10a3696cb7648494df79408aab
+DIST FBGEMM-2023.12.04.tar.gz 1004231 BLAKE2B 930ae36f4761901e1b22d7ce4a341f051158a23646bd1f5309f6eb98c1ca483e8aa4e5a6cfc44ced702f73f84e3398c1439799457a98d0d8a009702e335d5c03 SHA512 3c786572b4a69af2a32b360711014469ded69be580d0079ba79ab81cbaa964aab51e5a189e24f0ec7dc93402d761167898918a0ea0f86d556cad4b99f5858d8c