www-client/falkon: 25.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

www-client/falkon/Manifest

@@ -1 +1,2 @@
 DIST falkon-24.12.3.tar.xz 2654604 BLAKE2B 6e7f3f84a2a8218f837ae68c9f598354b1a0a527b01131231a300c0d8be62b5ac2dcac604d9b02441a169224cd1e0968d4d2934458bdbd576330ca73793936d3 SHA512 565dd3c0f9338745547cbe334e9af10157e34ddb0426a55ee95e43c56bfe08b81ea01bbd09da42a4fec4f8da48c15644b9753377ae20880575904dda4f7fa240
+DIST falkon-25.04.0.tar.xz 2705584 BLAKE2B 05fbefecf6bfda5b51218ee3a951b5aa54896709a68a5ea5f469eff0254034afac4aa195629405dd562419856ccfc017f8514184fd0f051f8de61a3e848c35ed SHA512 4f1b0eb491398386a0d2028f65e743a99d86caeba7ae1f8be140fc77314775a3ef70032a4b0863763d249431e294956fddeb7a0e97d606b920e31fed9e068043

www-client/falkon/falkon-25.04.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.9.0
+QTMIN=6.7.2
+PYTHON_COMPAT=( python3_{10..13} )
+inherit ecm gear.kde.org python-single-r1 xdg
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui,network,sql,sqlite,ssl,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtwebchannel-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6=[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	virtual/libintl
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:6
+		>=kde-frameworks/kcrash-${KFMIN}:6
+		>=kde-frameworks/kio-${KFMIN}:6
+		>=kde-frameworks/kjobwidgets-${KFMIN}:6
+		>=kde-frameworks/kwallet-${KFMIN}:6
+		>=kde-frameworks/purpose-${KFMIN}:6
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside-${QTMIN}:6[gui,positioning,uitools(-),webengine,widgets,\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:6"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:6
+"
+BDEPEND=">=dev-qt/qttools-${QTMIN}:6[linguist]"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF6Wallet)
+		$(cmake_use_find_package kde KF6KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}