kde-apps/konqueror: 25.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/konqueror/Manifest

@@ -1 +1,2 @@
 DIST konqueror-24.12.3.tar.xz 9774416 BLAKE2B db3060f0f962894ed063ab2c3a07e38c4edf6daef78cad16e59ba8f8b595164af739ed0c547b4e58f2aee8b44f36cdf69d6aac54c810fbdd9f5daf07a3bc2baa SHA512 b4a7ea33f12a9f0bdad671b3c704f54082b6cc856e9f8f58cfecdd188947e8cce66d3e51a77cdbc7e129f69a7c5524373fe1c6e9d3b4ce24835f0348bbd04d9d
+DIST konqueror-25.04.0.tar.xz 9824312 BLAKE2B bbbbdecc6c0187bda327b097c3fca7bcb7e5a6213667599e2b5cab591deffa1499875677a4a124d489dc9ee630d10d0f523f83ca0d15a87ae9d53dd329a1f72c SHA512 f873daf0b001eb4fe4cf6a3afb7bca03d95cb7a597e86f7dbc4ce60989dc3aacfde8ed10b0ad0244cd7ea8d8872698c2420a740ab0c8cc630b8725169a6cfe47

kde-apps/konqueror/konqueror-25.04.0.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=6.9.0
+QTMIN=6.7.2
+inherit flag-o-matic ecm gear.kde.org optfeature xdg
+
+DESCRIPTION="Web browser and file manager based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/konqueror/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE="activities speech"
+
+# 4 of 4 tests fail. Last checked for 4.0.3
+RESTRICT="test"
+
+# slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets,X,xml]
+	>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kbookmarks-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdesu-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/sonnet-${KFMIN}:6
+	sys-libs/zlib
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:6 )
+"
+DEPEND="${COMMON_DEPEND}
+	activities? ( kde-plasma/plasma-activities:6 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-apps/kio-extras-23.08.5-r100:5
+	kde-apps/kfind:6
+"
+
+src_prepare() {
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lmalloc
+
+	ecm_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Hunspell=ON # requires fixing bug 634122
+		$(cmake_use_find_package activities PlasmaActivities)
+		$(cmake_use_find_package speech QtTextToSpeech)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "bookmarks support" "kde-apps/keditbookmarks:${SLOT}"
+		optfeature "filemanager component" "kde-apps/dolphin:${SLOT}"
+		optfeature "SVG support" "kde-apps/svg:${SLOT}"
+	fi
+	xdg_pkg_postinst
+}