dev-util/cutter: add 2.4.1

Signed-off-by: John Helmert III <ajak@gentoo.org>

dev-util/cutter/Manifest

@@ -1 +1,2 @@
 DIST cutter-2.3.4.tar.gz 11608176 BLAKE2B f83cd117bdd1a9ea985b52d4029bd3874f92b08709ac50dd1c6a526aadd022e05f9b75586cf826cc6b46c2004cb6b3185c5770b8622bc3c6a7140307a9c1a98a SHA512 c35a7091aaf2c99a4595b48029017353092b178ed6a57cbe2f0d9758f1330d2521e3fc339558ffc0dfa500ace0510daded8591f7a04b0efa0209ba4f8a5e7d33
+DIST cutter-2.4.1.tar.gz 12303899 BLAKE2B e65cb3a235b71e0d7ce62d48c45f707d19a75d2ca2ab1a6ddae56632e4a7c23908db563b34ceb8fa60cbf1ad9d24166ff71efd84784faf149e24c1513257f7aa SHA512 f55118283329880c71c9ea54c31a060d25bfd0d5be81d7906488c29e5fce2a08fe34ad1144fc4bf0c0d6eae552d6c55da151067a00d8677b70bf7c0c328c4feb

dev-util/cutter/cutter-2.4.1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit cmake toolchain-funcs xdg-utils python-single-r1
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A Qt and C++ GUI for rizin reverse engineering framework"
+HOMEPAGE="https://cutter.re https://github.com/rizinorg/cutter/"
+SRC_URI="https://github.com/rizinorg/${PN}/releases/download/v${PV}/${MY_P}-src.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="CC-BY-SA-3.0 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="graphviz"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	dev-qt/qtbase:6[gui,network,opengl,widgets]
+	dev-qt/qt5compat:6
+	dev-qt/qtsvg:6
+	>=dev-util/rizin-0.8.1:=
+	graphviz? ( media-gfx/graphviz )"
+RDEPEND="${DEPEND}
+	!net-analyzer/cutter" # https://bugs.gentoo.org/897738
+BDEPEND="dev-qt/qttools:6[linguist]"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_CXX_COMPILER="$(tc-getCXX)"
+		-DCMAKE_C_COMPILER="$(tc-getCC)"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCUTTER_ENABLE_GRAPHVIZ="$(usex graphviz)"
+		-DCUTTER_ENABLE_KSYNTAXHIGHLIGHTING=OFF
+		-DCUTTER_ENABLE_PYTHON=ON
+		-DCUTTER_USE_ADDITIONAL_RIZIN_PATHS=OFF
+		-DCUTTER_USE_BUNDLED_RIZIN=OFF
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}