dev-util/rizin: add 0.8.1

Closes: https://bugs.gentoo.org/955883
Signed-off-by: John Helmert III <ajak@gentoo.org>

dev-util/rizin/Manifest

@@ -1,2 +1,4 @@
 DIST rizin-src-v0.7.4.tar.xz 18613012 BLAKE2B 0f55416fc73bf6122e3969aec286c1b77ee9d9495d71aee0c9dcdceb94d411aa9e12a05ad3a4aa8792f40d028e753c30b586bc397a9e72276b8e10fd058eab29 SHA512 47f077805d88ae10d69e9eb1a53a691b5c3c4b1604927934948cf8ff69731b23a1df8811297e2e5882a2d09b60a5601fcbc96abaa9342712f52335508f64a20a
+DIST rizin-src-v0.8.1.tar.xz 21334856 BLAKE2B 52da4a3cb522e540ce03e61691e029fe1e81f5367fc38a32fc32e8a99c00aa91701af8acee8308b8369495f76b0131a65565c11fe9b9bbc04b1f8f6e2c10cbf4 SHA512 da0de01199e0d314fb5023267918d26ae4748547e60c6ce10a81f32a6e6e5453694a5261cb16b48df1412ef405e4835feb9598fafe75787dcacbf0a5fa6225f9
+DIST rizin-testbins-71482f7194847b4ece45a9e53f28085b6bab40a4.tar.gz 189968184 BLAKE2B 410c43c5d0e9d79d9f378fd04921ba4e07560e060ee3d73338c0f083b7cb0b651d49864b6b0b36c4d1161340287ed187b7e267ac58c6ca6c019a8734cb6a5ae0 SHA512 d8120bf213e7c55c4de4756fd7a80e0629f6719b30f661bd5826065c8fa7b570f62b376956ef24570ecaaa9c24b7241119d8d94bd2f60bb9155c5dd06faa729e
 DIST rizin-testbins-ced304a8d886b2ba189027a86b2e9d949ab311dd.tar.gz 187060498 BLAKE2B 612d6f13f609e1dcdd72e37ae18d96680cacbb788aebc101ca6e78e96712b7142ee73ba9157163a49152810a6223524d15e211a7db81c4aa2efcb4ed4572d1de SHA512 07d9c66d7ffbe8954a6a8c8ac7da75e5a1d0258533e32d223d1267826c9e8b3182bf8e2d55ca8d683992059b1068044dbbb662774e533d70bad7806b0d343369

dev-util/rizin/rizin-0.8.1.ebuild

@@ -0,0 +1,100 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+# This is the commit that the CI for the release commit used
+BINS_COMMIT="71482f7194847b4ece45a9e53f28085b6bab40a4"
+
+inherit meson python-any-r1
+
+DESCRIPTION="reverse engineering framework for binary analysis"
+HOMEPAGE="https://rizin.re/"
+
+SRC_URI="mirror+https://github.com/rizinorg/rizin/releases/download/v${PV}/rizin-src-v${PV}.tar.xz
+	test? ( https://github.com/rizinorg/rizin-testbins/archive/${BINS_COMMIT}.tar.gz -> rizin-testbins-${BINS_COMMIT}.tar.gz )"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="Apache-2.0 BSD LGPL-3 MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+
+# Need to audit licenses of the binaries used for testing
+RESTRICT="test? ( fetch ) !test? ( test )"
+
+# TODO: unbundle dev-libs/blake3
+RDEPEND="
+	app-arch/lz4:0=
+	app-arch/xz-utils
+	app-arch/zstd:=
+	>=dev-libs/capstone-5:0=
+	dev-libs/libmspack
+	dev-libs/libzip:0=
+	dev-libs/openssl:0=
+	dev-libs/libpcre2:0=[jit]
+	>=dev-libs/tree-sitter-0.19.0:=
+	dev-libs/xxhash
+	sys-apps/file
+	sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.4.0-never-rebuild-parser.patch"
+	# "${FILESDIR}/${PN}-0.7.3-force-local-tree-sitter-c.patch"
+)
+
+src_prepare() {
+	default
+
+	local py_to_mangle=(
+		librz/core/cmd_descs/cmd_descs_generate.py
+		sys/clang-format.py
+		test/fuzz/scripts/fuzz_rz_asm.py
+		test/scripts/gdbserver.py
+	)
+
+	python_fix_shebang "${py_to_mangle[@]}"
+
+	# https://github.com/rizinorg/rizin/issues/3459
+	sed -ie '/dyld_chained_ptr_arm64e_auth/d' test/unit/test_bin_mach0.c || die
+
+	if use test; then
+		cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}/test/bins" || die
+		cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}" || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcli=enabled
+		-Duse_sys_capstone=enabled
+		-Duse_sys_libmspack=enabled
+		-Duse_sys_libzip=enabled
+		-Duse_sys_libzstd=enabled
+		-Duse_sys_lz4=enabled
+		-Duse_sys_lzma=enabled
+		-Duse_sys_magic=enabled
+		-Duse_sys_openssl=enabled
+		-Duse_sys_pcre2=enabled
+		-Duse_sys_tree_sitter=enabled
+		-Duse_sys_xxhash=enabled
+		-Duse_sys_zlib=enabled
+
+		$(meson_use test enable_tests)
+		$(meson_use test enable_rz_test)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# We can select running either unit or integration tests, or all of
+	# them by not passing --suite. According to upstream, integration
+	# tests are more fragile and unit tests are sufficient for testing
+	# packaging, so only run those.
+	meson_src_test --suite unit
+}