media-video/gaupol: add 1.16

Signed-off-by: Louis Sautier <sbraz@gentoo.org>

media-video/gaupol/Manifest

@@ -1 +1,2 @@
 DIST gaupol-1.15.tar.gz 593412 BLAKE2B af21c3fac16a9e6a861ba93679f59134b68ab780812115048646b74a6524e230bb02a62454e8a42bdc436dfd08441f3e103a04b112c9d721e12d291e5e8cfbc7 SHA512 899dac0a8827e7b1b61ac9745f5fb39376eed1e4ccf928c3442350f6d8bb27f743923e1d321f1215f422b6e1d1d4e13cfe56adc2b4c358f22f6647a642726889
+DIST gaupol-1.16.tar.gz 594322 BLAKE2B 5a335504a9fde907faee2ec6a8a4b562004d8be68cf8936fa74ab69bbd518c1972892709cd8eb9abb9cde2051ee873c15dfc495624dd11d389c2f52300668c90 SHA512 d590094d796f6d47e78da939f6098b78b77dbbfb8e9e518bd93807c86caae7abb528991a2688df7c009ed743267af70b3aa1506c8dd63408fa1939a119e786b1

media-video/gaupol/gaupol-1.16.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 optfeature virtualx xdg-utils
+
+DESCRIPTION="Editor for text-based subtitle files"
+HOMEPAGE="https://otsaloma.io/gaupol/"
+SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	app-text/iso-codes
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+"
+BDEPEND="
+	sys-devel/gettext
+	test? (
+		app-dicts/myspell-en
+		app-text/gspell[introspection]
+		|| (
+			app-text/enchant[hunspell]
+			>=app-text/enchant-2.2.8[nuspell]
+		)
+	)
+"
+
+DOCS=( {AUTHORS,NEWS,README{,.aeidon}}.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.12-fix-prefix.patch
+)
+
+distutils_enable_tests pytest
+
+python_test() {
+	virtx epytest
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+
+	# To check which GStreamer plugins are required (vaapisink is mentioned in the code but it is not used):
+	# plugins=$(qlist -e gaupol | xargs grep -ho 'Gst.ElementFactory.*' | cut -d'"' -f2 | sort -u | grep -vFx vaapisink)
+	# xargs -n1 gst-inspect-1.0 <<< "$plugins" | awk '/Filename/ {print $2}' | sort -u | xargs qfile
+	optfeature "built-in video player" \
+		"media-libs/gstreamer[introspection] media-libs/gst-plugins-base[pango] media-plugins/gst-plugins-gtk"
+	optfeature "external video player" media-video/mpv media-video/mplayer media-video/vlc
+
+	optfeature "spellchecking (does not include dictionaries)" "app-text/gspell[introspection]"
+	# To list dictionaries supported by gaupol:
+	# python3 -c 'import aeidon; print(*aeidon.SpellChecker.list_languages(), sep="\n")'
+	optfeature "spellchecking with app-dicts/myspell-* dictionaries using the nuspell backend" \
+		"app-text/enchant[nuspell]"
+	optfeature "spellchecking with app-dicts/myspell-* dictionaries using the hunspell backend" \
+		"app-text/enchant[hunspell]"
+	optfeature "spellchecking with app-dicts/aspell-* dictionaries" \
+		"app-text/enchant[aspell]"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}