sys-apps/fwupd-efi: add 1.8

Some progress is made w/ LLVM in this release (thanks to Pepper Gray for
reporting bugs upstream and sending PRs there!) but isn't quite there yet.

Bug: https://bugs.gentoo.org/949655
Signed-off-by: Sam James <sam@gentoo.org>

sys-apps/fwupd-efi/Manifest

@@ -1,2 +1,3 @@
 DIST fwupd-efi-1.6.tar.xz 39940 BLAKE2B 906f90a3187fb7d180dab22941d255220e3d56c2058ff6a5a260b0cd62c90e9c784a7c091da376111f23d02561abdec71958afec63c54134a77aac71deec20bc SHA512 37d3c1348bdead620e626a3e602dc6cd774c47d24ca18a3bf6aee071300d658bc4d37e6ec74fcd20f9b345141d69ea3343d44b9408af4759ad65ef10b72ead69
 DIST fwupd-efi-1.7.gh.tar.gz 44913 BLAKE2B 4e73eb5eea70817beeff52d4bfebb988ced1359299eb3d53db989ae70dbc6fa77ff98ced703a00fbea2b41f5a856e246ecafecdc457d1a35499dd60a57a9a2a8 SHA512 db0857e76964c6e36dd8708fe3b4a0b56290543c374e40a9e1f0919e0016d59de6bd6d2e4f43fb2ddd706841917b60d36da086e1290d3351283504d287083a7e
+DIST fwupd-efi-1.8.gh.tar.gz 46198 BLAKE2B b72f417b030a2531f4e6bb3c68eb28e99eb9a52038980cc30191d4884586d90342bd5fffbfc587acc29c877078b61ab42b045f0b78d2256da51b6f1fbf0bd9fe SHA512 bd361eb60397850af025228ea9f4efbf289f8e1c2612f240ae4c5ffee8caea15c31aa0748c06e57b28a7f38b8c2708147a228d8a99077798f4435436f12e092e

sys-apps/fwupd-efi/fwupd-efi-1.8.ebuild

@@ -0,0 +1,65 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit meson python-any-r1 secureboot
+
+DESCRIPTION="EFI executable for fwupd"
+HOMEPAGE="https://fwupd.org"
+
+if [[ ${PV} = *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fwupd/fwupd-efi.git"
+else
+	SRC_URI="https://github.com/fwupd/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+# uswid is used as a CLI tool, hence no Pythonic stuff
+BDEPEND="
+	$(python_gen_any_dep '
+		dev-python/pefile[${PYTHON_USEDEP}]
+	')
+	sys-apps/uswid
+	virtual/pkgconfig
+"
+DEPEND=">=sys-boot/gnu-efi-3.0.18"
+
+python_check_deps() {
+	python_has_version "dev-python/pefile[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	secureboot_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	python_fix_shebang "${S}/efi"
+}
+
+src_configure() {
+	local emesonargs=(
+		-Defi-libdir="${EPREFIX}"/usr/$(get_libdir)
+		-Defi_sbat_distro_id="gentoo"
+		-Defi_sbat_distro_summary="Gentoo GNU/Linux"
+		-Defi_sbat_distro_pkgname="${PN}"
+		-Defi_sbat_distro_version="${PVR}"
+		-Defi_sbat_distro_url="https://packages.gentoo.org/packages/${CATEGORY}/${PN}"
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	secureboot_auto_sign
+}