dev-libs/libjcat: add 0.2.5 (unkeyworded)

Unkeyworded because of test failures. Note I've chosen GnuTLS as we had
before because
a) supporting both gnutls & openssl is a bit awkward, and
b) ed25519 needs gnutls anyway, it seems

Bug: https://github.com/hughsie/libjcat/issues/195
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/libjcat/Manifest

@@ -1 +1,2 @@
 DIST libjcat-0.2.3.tar.xz 66188 BLAKE2B 200cac29d355cce54a4d722bcdd5dcd88e2aea59c31fb43a37cf4a7272cd7d996acafa3e4e70e15fdd59174be158b9c5134acef6a722504f97835095f63eb274 SHA512 ff4627c3917b10eb5acce0c0c2f583f6cebe8d9c7501ff3cbb9a8b419db62761d6b82674786cbfa00fe66d30a7699bc87c37e76648e45884a97523d68ac6ae15
+DIST libjcat-0.2.5.tar.xz 71852 BLAKE2B adeaecd337dbd7e854700ff78c24c422bd3f0abe8cbd2d04611223023921b51c0ef21e3a3475ac189b7c20c41db22208ab3db9d1b7cd47c4c6448a7bb3a9772b SHA512 84b4111d80a2d9e6dccc39b120b97b7128a9aef716cce2426acc5b36199472d6d6acd291affeffcd48156ed07189c09a04559282772ab8e1dd8f321446141407

dev-libs/libjcat/libjcat-0.2.5.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+PYTHON_REQ_USE="xml(+)"
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files"
+HOMEPAGE="https://github.com/hughsie/libjcat"
+SRC_URI="https://github.com/hughsie/libjcat/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+# https://github.com/hughsie/libjcat/issues/195
+#KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+ed25519 +gpg gtk-doc +introspection +man +pkcs7 test vala"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib:=
+	ed25519? ( net-libs/gnutls:= )
+	gpg? (
+		app-crypt/gpgme:=
+		dev-libs/libgpg-error
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	pkcs7? ( net-libs/gnutls:= )
+	vala? ( dev-lang/vala:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	')
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( sys-apps/help2man )
+	test? ( net-libs/gnutls[tools] )
+"
+
+python_check_deps() {
+	python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use vala && vala_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use ed25519 gnutls_ed25519)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use gpg)
+		$(meson_use introspection)
+		$(meson_use man)
+		$(meson_use pkcs7 gnutls_pkcs7)
+		-Dopenssl_pkcs7=false
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -rf \
+			"${ED}"/usr/libexec/installed-tests \
+			"${ED}"/usr/share/installed-tests \
+			|| die
+	fi
+}