dev-python/anyioutils: New package, v0.7.1

Needed by dev-python/zmq-anyio, which is needed by dev-python/ipykernel.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/anyioutils/Manifest

@@ -0,0 +1 @@
+DIST anyioutils-0.7.1.tar.gz 14675 BLAKE2B 7b1d983613b3c770af9c09eabf2332651fce30a1bbc58e63e6a9a7e2bd97c6c59591927f034d0fde97454aae6b7fcf23dced19cb2cc64ac58ed1f1b7ed110fd5 SHA512 f259ee78c31b15f4f827158d251471229a4b1fb280cca6e0f08edadc4bde27d7e991cd27c13aae2510a63f33410f5e96f656b95ce65dd72d91e572df5c62703b

dev-python/anyioutils/anyioutils-0.7.1.ebuild

@@ -0,0 +1,46 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Utility classes and functions for AnyIO"
+HOMEPAGE="
+	https://github.com/davidbrochart/anyioutils/
+	https://pypi.org/project/anyioutils/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-4.8.0[${PYTHON_USEDEP}]
+	<dev-python/outcome-2[${PYTHON_USEDEP}]
+	>=dev-python/outcome-1.3.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires aioguest
+		tests/test_guest.py::test_host_trivial_guest_asyncio
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p anyio
+}

dev-python/anyioutils/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">davidbrochart/anyioutils</remote-id>
+		<remote-id type="pypi">anyioutils</remote-id>
+	</upstream>
+</pkgmetadata>