dev-python/tavern: Bump to 2.12.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/tavern/Manifest

@@ -1 +1,2 @@
 DIST tavern-2.11.0.gh.tar.gz 233387 BLAKE2B b1b26e7d9fc4069c7056072ab01c9937245304982f78df236e9bcaa795feec6a1db7192532dba6d17d362af874bffce601bb9652b5f1ecda99c59387f717bb15 SHA512 456fa6ebfc6f47ff9a473e3f416aff9f88b1f9b25c898786d15472072859e1659c089a9c668e6ddc4ecfc0cc8c233417d4768e0f7228800995509a5a34294faf
+DIST tavern-2.12.0.gh.tar.gz 239452 BLAKE2B a9bef9dbebbdf25f09f158a3bf908769bb56280ff7939557fce454f4169093e362abf1d1cf36f220cd398bcde1c19f7f545d2f4d4ff2318bebd91da69f88c155 SHA512 1b1d997372330b14dc7b106762538ca16646fdf84b344c9db81ab1896678dea2d96c4c801c941c33ae856c670ec405962b76b5c044d1b8e94938effe675cef5c

dev-python/tavern/tavern-2.12.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+	>=dev-python/paho-mqtt-1.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7[${PYTHON_USEDEP}]
+	>=dev-python/python-box-6[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/simpleeval-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/faker[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires grpc
+		tests/unit/test_extensions.py::TestGrpcCodes
+		# broken with paho-mqtt-2
+		tests/unit/test_mqtt.py::TestClient::test_context_connection_success
+	)
+	local EPYTEST_IGNORE=(
+		# require grpc*
+		tavern/_plugins/grpc
+		tests/unit/tavern_grpc
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p tavern
+}