dev-libs/libsavitar: add 4.12.1

Signed-off-by: Marek Szuba <marecki@gentoo.org>

dev-libs/libsavitar/Manifest

@@ -1 +1,2 @@
+DIST libsavitar-4.12.1.tar.gz 100730 BLAKE2B cb9dd3ed6802e88235769f70092dbd50113d107b3d2ec17851120338ad6b6ee809c1243f406ee0c96358e5e618d883640e2c3ff9c7f3b41fa6e3a4993939c044 SHA512 c848730cca44b942cd0aba343880a68b23f1bfe95b3348cf1d9d490d9a99be3db9d1940ae473a74ad695823404fab86b728327783c8cc3cfb04ebff8cc6a1b3c
 DIST libsavitar-4.9.1.tar.gz 100496 BLAKE2B 7700f110522298905c1e4cf42529e83c06c337ac826007db2fca8abf462abcb8dd9245d2d81773ba3e6663d9afa093685bf955a1cc7e27d48fc904913e56d62f SHA512 2b291a17603922a4a06292282392015cf381a813b5f9a374e8cb35da6c0701ead72cbf76f17e763793225885a4209b49e73114f462b40d6999f95db6de887a44

dev-libs/libsavitar/libsavitar-4.12.1.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake python-single-r1
+
+MY_PN="libSavitar"
+
+DESCRIPTION="C++ implementation of 3mf loading with SIP python bindings"
+HOMEPAGE="https://github.com/Ultimaker/libSavitar"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+python static-libs test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/pugixml
+	$(python_gen_cond_dep '
+		<dev-python/sip-5[${PYTHON_USEDEP}]
+	')"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-cpp/gtest
+		dev-cpp/tbb
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+BUILD_DIR="${S}/build"
+
+PATCHES=( "${FILESDIR}/${PN}-4.7.0-use-system-pugixml.patch" )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# remove bundled pugixml
+	rm -r "${S}"/pugixml || die
+
+	find "${S}"/src -type f -name '*.cpp' -o -name '*.h' | xargs sed -i \
+		-e 's "../pugixml/src/pugixml.hpp" <pugixml.hpp> g' || die
+
+	if use test; then
+		find "${S}"/tests -type f -name '*.cpp' -o -name '*.h' | xargs sed -i \
+			-e 's "../pugixml/src/pugixml.hpp" <pugixml.hpp> g' || die
+	fi
+
+	# find SIP for current python version, not the latest installed
+	sed -i -e "s/find_package(Python3 3.4 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED/g" \
+		CMakeLists.txt cmake/FindSIP.cmake || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PYTHON=$(usex python ON OFF)
+		-DBUILD_STATIC=$(usex static-libs ON OFF)
+		-DBUILD_TESTS=$(usex test ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_src_test
+}