dev-libs/libcharon: add 4.12.1

Signed-off-by: Marek Szuba <marecki@gentoo.org>

dev-libs/libcharon/Manifest

@@ -1 +1,2 @@
+DIST libcharon-4.12.1.tar.gz 151783 BLAKE2B 54cac090a924ee086e15fddc0cd2acc8dfbc3dfd2dc91b27ffb1d81a64dcf30a46bf62e2c443d8de46a6f2a02e6d06dc1ea454d19f57f7dd93d5f81a44477dba SHA512 dcc0b89703e36e8f3d508bbda91b6fcc8313ac09c4d5e09cc6f0770ccdde18e421daa7e6b52958c5705dbb6987961635e3e31a61810ba54bf8b842af7afba94d
 DIST libcharon-4.9.1.tar.gz 151243 BLAKE2B 8557efe4667a83297a4bcfc8307e2322a379e52d50ad1648d873a923e182b3be1651a13c7402ac041fd134036a75a42e825adf2cc27271af218db44af7e48473 SHA512 41d611f8d3bf0f762a38a00c159104df04b73cd5c4f7e9ebcfe3ac9cdd0c8e31e505c4fd4ef8f8a6f1c02bf882bb3e14ea4e92c8b15169a91cbd1815e36310fa

dev-libs/libcharon/libcharon-4.12.1.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake python-single-r1
+
+MY_PN="libCharon"
+
+DESCRIPTION="This library facilitates communication between Cura and its backend"
+HOMEPAGE="https://github.com/Ultimaker/libCharon"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+client +dbus test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="
+	${PYTHON_DEPS}
+	dbus? (
+		acct-group/ultimaker
+		acct-user/ultimaker
+		sys-apps/dbus
+	)"
+
+DEPEND="${PYTHON_DEPS}
+	test? (
+		$(python_gen_cond_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	# use current python version, not the latest installed
+	# fix python install location
+	sed -i \
+		-e "s:find_package(Python3 3.4 REQUIRED:find_package(Python3 ${EPYTHON##python} EXACT REQUIRED:g" \
+		-e "s:lib\${LIB_SUFFIX}/python\${Python3_VERSION_MAJOR}\.\${Python3_VERSION_MINOR}/site-packages:$(python_get_sitedir):g" \
+		CMakeLists.txt || die
+
+	sed -i -e "s:/usr/lib/python3/dist-packages/Charon/Service/main.py:$(python_get_sitedir)/Charon/Service/main.py:g" service/charon.service || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_CLIENT=$(usex client ON OFF)
+		-DINSTALL_SERVICE=$(usex dbus ON OFF)
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	if use dbus ; then
+		elog "To start the Charon File Metadata service at boot, add it to the default runlevel with:"
+		elog "    systemctl enable charon"
+	fi
+}