dev-libs/liborcus: add 0.20.0

Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/liborcus/Manifest

@@ -1 +1,2 @@
 DIST liborcus-0.19.2.tar.xz 2211268 BLAKE2B 4ee3fd2fb122d3a9840cb92452bf8a6d3d54b7b50a32be84e1bb08dfe2e2abc2de80098d9460b6bd82d0249304a7ba5c39b18ace3f69150ba71e16ef14795ca4 SHA512 c955490f57e91615278a83bb48726025cd5f8059b97ed5532f770199e134ca511c7ee6b0cd0a9d3a2d54208a5fdd19117054e95e818162ea568052fa11b21d4e
+DIST liborcus-0.20.0.tar.gz 3223041 BLAKE2B ab281b3ab7dd859be68d4dbed089e578101d3133e457bbbfc4becaf12ac89640b697ed9a71eb7344a8b92d17d415964d4360e057b5233ff1c7782e22491e8bad SHA512 5de1ff0e0dfc0cb3a4e846dec28e0c9c0c5f2412119ddcd3a1e0be704c2c2571c075785d9b7047dd4aa5498fd180b5fd4b72528bacd7a6168e26adbd7654a35b

dev-libs/liborcus/liborcus-0.20.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit autotools python-single-r1
+
+DESCRIPTION="Standalone file import filter library for spreadsheet documents"
+HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
+
+if [[ ${PV} == *9999* ]]; then
+	MDDS_SLOT="1/3.0"
+	EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
+	inherit git-r3
+else
+	MDDS_SLOT="1/3.0"
+	# "404s" but serves HTML for 0.20.0
+	#SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
+	SRC_URI="https://gitlab.com/api/v4/projects/orcus%2Forcus/packages/generic/source/${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/0.20" # based on SONAME of liborcus.so
+IUSE="python +spreadsheet-model test tools"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=[zlib(+)]
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+	spreadsheet-model? ( dev-libs/libixion:${SLOT} )
+"
+DEPEND="
+	${RDEPEND}
+	dev-util/mdds:${MDDS_SLOT}
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--without-benchmark
+		--disable-werror
+		$(use_enable python)
+		$(use_enable spreadsheet-model)
+		$(use_with tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	use python && python_optimize
+	find "${D}" -name '*.la' -type f -delete || die
+}

dev-libs/liborcus/liborcus-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -14,8 +14,10 @@ if [[ ${PV} == *9999* ]]; then
 	EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
 	inherit git-r3
 else
-	MDDS_SLOT="1/2.1"
-	SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
+	MDDS_SLOT="1/3.0"
+	# "404s" but serves HTML for 0.20.0
+	#SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
+	SRC_URI="https://gitlab.com/api/v4/projects/orcus%2Forcus/packages/generic/source/${PV}/${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 fi
 
@@ -32,7 +34,8 @@ RDEPEND="
 	python? ( ${PYTHON_DEPS} )
 	spreadsheet-model? ( dev-libs/libixion:${SLOT} )
 "
-DEPEND="${RDEPEND}
+DEPEND="
+	${RDEPEND}
 	dev-util/mdds:${MDDS_SLOT}
 "