dev-libs/libixion: add 0.20.0

Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/libixion/Manifest

@@ -1 +1,2 @@
 DIST libixion-0.19.0.tar.xz 536540 BLAKE2B 2bd8db83f926d553b1b6c78eb3e735e9911dbdd3cb95105fca04fd560099f38c5e4834d5887b1b0e6d44343e0da9b0fa0264f00c931a6b04b7e4c70996f819b2 SHA512 f06edbcf5ae7459a46e01273952ce6fbc4e8f2b7782c7e07645dc30e102f20f542e449acafc26484765207b10656e0b350f4108cbf1e03947ee7267254cf6f97
+DIST libixion-0.20.0.tar.xz 544780 BLAKE2B eca4149bc84756912a8b5c6c34c99b07c22001f28acc10a45caeb4def4b4602938fdfffaf423472afe3c27f763a1d3963a3956df6ae89e87abddc2a8e43d076b SHA512 f36e5312db440a528ceab21bce6ea0d94f548b0a3893f214693ebcf5ab81dee001b23324f5a745059ab85fd54b0d3fb53084f0b1fb9ff58b59c18c341c1ba2aa

dev-libs/libixion/libixion-0.20.0.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit libtool python-single-r1
+
+DESCRIPTION="General purpose formula parser & interpreter"
+HOMEPAGE="https://gitlab.com/ixion/ixion"
+
+if [[ ${PV} == *9999* ]]; then
+	MDDS_SLOT="1/3.0"
+	EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
+	inherit git-r3 autotools
+else
+	MDDS_SLOT="1/2.1"
+	# Invalid as of 0.20.0, serves HTML
+	#SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+	SRC_URI="https://gitlab.com/api/v4/projects/ixion%2Fixion/packages/generic/source/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/0.20" # based on SONAME of libixion.so
+IUSE="debug python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-util/mdds:${MDDS_SLOT}
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	if [[ ${PV} == *9999* ]]; then
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug debug-utils)
+		$(use_enable debug log-debug)
+		$(use_enable python)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}

dev-libs/libixion/libixion-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -15,7 +15,9 @@ if [[ ${PV} == *9999* ]]; then
 	inherit git-r3 autotools
 else
 	MDDS_SLOT="1/2.1"
-	SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+	# Invalid as of 0.20.0, serves HTML
+	#SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+	SRC_URI="https://gitlab.com/api/v4/projects/ixion%2Fixion/packages/generic/source/${PV}/${P}.tar.xz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 fi