x11-wm/qtile: Bump to 0.30.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2025-01-07 19:30:21 +01:00
parent 665f510aab
commit 30e405d8cd
2 changed files with 118 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST qtile-0.28.1.tar.gz 601217 BLAKE2B 04f24c5b628e1c3d0eca395135ef0d0093af5a57d23aea751e76197da4f148ae679a9fb650e2589e5f2e253673cab86642e3f0695ac219641c65192eb9a37274 SHA512 95b4d95206aeac4bb59d47c94eb93b55ac413681050345a0d61cdb19b71dd785bb6c13c0161757b9bfa5e8d0ce345fcf64eea04fc44b2f596a65b70f5da5d32e
DIST qtile-0.29.0.tar.gz 607026 BLAKE2B 71a282b08b6d15e08f616e28a59a632a76ef4a180788177606873dec7870d715fa96403ece6745de8898716e863b7462a745426f59fb13fd40ba87207be30d24 SHA512 745a9a79209c0dbac5e49b8ee90d567204fd022c63e9321afbb6a3a064f8e9376fdbbe67a5115e50b251d28129f4907761cbbd3e0b3d2e0676e047ef8369c92c
DIST qtile-0.30.0.tar.gz 617632 BLAKE2B c26d51d7e31ef058a5a08ef8ef47ccce19bc59b9337d0dc1d874b2c4047ea2e1827cc694a9199ea808d22b7845a8bb019eb85a1912ddfb00801763b43e62b0f2 SHA512 218b7ba42315884faf11460c18a9fa8f34a3284d3fd4632c24997657e7ec659e337be9b0845e00dc7d4106828d7e5efcfd401ea7d031e0725598e60ad4172147
+117
View File
@@ -0,0 +1,117 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=standalone
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 pypi virtualx
DESCRIPTION="A full-featured, hackable tiling window manager written in Python"
HOMEPAGE="
https://qtile.org/
https://github.com/qtile/qtile/
https://pypi.org/project/qtile/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="pulseaudio wayland"
DEPEND="
>=dev-python/cairocffi-1.6.0[${PYTHON_USEDEP}]
>=dev-python/cffi-1.1.0:=[${PYTHON_USEDEP}]
"
RDEPEND="
${DEPEND}
dev-python/dbus-fast[${PYTHON_USEDEP}]
dev-python/pygobject[${PYTHON_USEDEP}]
>=dev-python/xcffib-1.4.0[${PYTHON_USEDEP}]
x11-libs/cairo[X,xcb(+)]
x11-libs/libnotify[introspection]
x11-libs/pango
pulseaudio? (
dev-python/pulsectl-asyncio[${PYTHON_USEDEP}]
media-libs/libpulse
)
wayland? (
>=dev-python/pywayland-0.4.17[${PYTHON_USEDEP}]
>=dev-python/pywlroots-0.17[${PYTHON_USEDEP}]
)
"
BDEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
dev-python/libcst[${PYTHON_USEDEP}]
media-gfx/imagemagick[X]
x11-base/xorg-server[xephyr,xvfb]
)
wayland? (
>=dev-python/pywayland-0.4.17[${PYTHON_USEDEP}]
>=dev-python/pywlroots-0.17[${PYTHON_USEDEP}]
)
"
: ${EPYTEST_TIMEOUT:=180}
distutils_enable_tests pytest
python_prepare_all() {
distutils-r1_python_prepare_all
sed -e "s/can_import(\"wlroots.ffi_build\")/$(usex wayland True False)/" \
-i setup.py || die
mkdir bin || die
}
src_compile() {
local -x CFFI_TMPDIR=${T}
distutils-r1_src_compile
}
src_test() {
virtx distutils-r1_src_test
}
python_test() {
local EPYTEST_DESELECT=(
# mypy stuff
test/test_check.py
test/migrate/test_check_migrations.py
# TODO: this test clearly requires x11 — so why is wayland
# variant being run?
'test/backend/x11/test_window.py::test_urgent_hook_fire[wayland-2]'
# TODO
test/test_hook.py::test_net_wm_icon_change
)
# force usage of built module
rm -rf libqtile || die
# some tests expect bin/qtile
ln -fs "$(type -P qtile)" bin/qtile || die
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x TZ=UTC
nonfatal epytest -p rerunfailures --reruns=5 \
--backend=x11 $(usev wayland '--backend=wayland') ||
die -n "Tests failed with ${EPYTHON}"
}
python_install_all() {
local DOCS=( CHANGELOG README.rst )
distutils-r1_python_install_all
insinto /usr/share/xsessions
doins resources/qtile.desktop
insinto /usr/share/wayland-sessions
doins resources/qtile-wayland.desktop
exeinto /etc/X11/Sessions
newexe "${FILESDIR}"/${PN}-session-r1 ${PN}
}