dev-python/dbus-fast: New package, v2.24.4

New fork of dev-python/dbus-next, needed for x11-wm/qtile bump.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/dbus-fast/Manifest

@@ -0,0 +1 @@
+DIST dbus-fast-2.24.4.gh.tar.gz 178320 BLAKE2B 790935c94b8c5984993bbbc7741cca1ab6c232e8a58266030318c774dcbdd77b3712fbb5ab3b3c6197f86eb8c0be0d8626e9dfcabf50a1a485be8d80334721fe SHA512 e08a1b8c028cf33f7055621b502ffdffb1d9c79875b9f9d05afca401cdc583ae97bb029706002ad0e94e2ce8ccf3a992fe9cc9c023e87f64d04bb581b2e9f263

dev-python/dbus-fast/dbus-fast-2.24.4.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A faster version of dbus-next"
+HOMEPAGE="
+	https://github.com/bluetooth-devices/dbus-fast/
+	https://pypi.org/project/dbus-fast/
+"
+SRC_URI="
+	https://github.com/Bluetooth-Devices/dbus-fast/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.4.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/pycairo-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.42.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.19[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+src_test() {
+	local dbus_params=(
+		$(dbus-daemon --session --print-address --fork --print-pid)
+	)
+	local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+	virtx distutils-r1_src_test
+
+	kill "${dbus_params[1]}" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# interface not found on this object: org.freedesktop.DBus.Debug.Stats
+		tests/client/test_signals.py::test_signals
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest -o addopts= -p asyncio || die
+}

dev-python/dbus-fast/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">bluetooth-devices/dbus-fast</remote-id>
+		<remote-id type="pypi">dbus-fast</remote-id>
+	</upstream>
+</pkgmetadata>