xfce-extra/xfce4-screensaver: Bump to 4.20.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-screensaver/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-screensaver-4.18.4.tar.bz2 896547 BLAKE2B ba240b37cad4f2c7f7f9c9cfa9bc280e2329f5565c98315920429b3ca0c4e333b528fbf8390761d86253ef2e58f1226097d123a62e4cf5276cceaf21f316421c SHA512 1cc30b8262ee53446671ac3dd28b108aed13c37aa565a34809285f14fb5ef9f883c5317cfb798a4012e034a8997ad05c4a402128e10fd263a58c2770d0feefaa
 DIST xfce4-screensaver-4.20.0.tar.xz 273588 BLAKE2B ceba3364da0b89cc72c3bdf7f6064056df92f630d47af32987e4a2e99dfe16d4f369a6ea786513c94d2d6fa3931076c91f0ea009aa16411115132e4108c58ba5 SHA512 06783408be0058376887ee9a72688727c181cb7fdcba1da28c8c34cd66e7de40e930f0efec44f98ecda7fe53e459679143e32234e0ac109ee84e1e3d5c3f773b
+DIST xfce4-screensaver-4.20.1.tar.xz 256848 BLAKE2B b6c7539d3efa56be277282f96c9ea558ad200b3d9370e8f128e19bbcf719e4e87a90d4241d9ed0ecf008a8c754987f399d4ddfa6bfa93af892aa2f02ed68929a SHA512 1102b697d30ebfc2466c808d25177d1b9abe68668ab28cf9b228ed5ed348a25e5d3a1fb887a8b9d303dacb36b88f7df7a3f6fe317ee9c357e13d2e3be776ad30

xfce-extra/xfce4-screensaver/xfce4-screensaver-4.20.1.ebuild

@@ -0,0 +1,111 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
+HOMEPAGE="
+	https://docs.xfce.org/apps/screensaver/start
+	https://gitlab.xfce.org/apps/xfce4-screensaver/
+"
+SRC_URI="
+	https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.xz
+"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="elogind +locking pam systemd wayland X"
+REQUIRED_USE="
+	|| ( wayland X )
+"
+
+DEPEND="
+	>=dev-libs/dbus-glib-0.30
+	>=dev-libs/glib-2.50.0:2
+	>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+	>=xfce-base/garcon-4.16.0:=
+	>=xfce-base/libxfce4ui-4.18.4:=
+	>=xfce-base/libxfce4util-4.16.0:=
+	>=xfce-base/xfconf-4.16.0:=
+	wayland? (
+		>=dev-libs/wayland-1.15
+		gui-libs/libwlembed:=[gtk]
+		>=xfce-base/libxfce4windowing-4.19.2:=
+	)
+	X? (
+		>=x11-libs/libwnck-3.20:3
+		>=x11-libs/libX11-1.6.7:=
+		>=x11-libs/libXScrnSaver-1.2.3:=
+		>=x11-libs/libXext-1.0.0:=
+		>=x11-libs/libxklavier-5.2:=
+	)
+	elogind? ( sys-auth/elogind )
+	locking? (
+		pam? ( sys-libs/pam )
+	)
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+DEPEND+="
+	wayland? (
+		>=dev-libs/wayland-protocols-1.20
+	)
+"
+BDEPEND="
+	dev-util/glib-utils
+	sys-apps/dbus
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local auth_scheme session_manager
+
+	if use locking; then
+		if use pam; then
+			auth_scheme=pam
+		else
+			auth_scheme=pwent
+		fi
+	else
+		auth_scheme=none
+	fi
+	if use systemd; then
+		session_manager=systemd
+	elif use elogind; then
+		session_manager=elogind
+	else
+		session_manager=none
+	fi
+
+	local emesonargs=(
+		-Dauthentication-scheme=${auth_scheme}
+		-Dsession-manager=${session_manager}
+		$(meson_feature X x11)
+		$(meson_feature wayland)
+		-Dxscreensaverhackdir="${EPREFIX}/usr/$(get_libdir)/misc/xscreensaver"
+		-Dkbd-layout-indicator=true
+		# disable docbook for now
+		-Ddocs=disabled
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		# used only with -Dauthentication-scheme=pam
+		-Dpam-auth-type=system
+		# used only with -Dauthentication-scheme=pwent
+		-Dshadow=true
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}