net-misc/remmina: add 1.4.41

Signed-off-by: Ben Kohler <bkohler@gentoo.org>
2026-09-23 16:49:10 -07:00 · 2025-08-15 10:28:37 -05:00
parent 6d698012a1
commit b4e932809d
2 changed files with 105 additions and 0 deletions
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1 +1,2 @@
 DIST Remmina-v1.4.40.tar.bz2 2176307 BLAKE2B cb5db34af818e3aec265db6c75610312ba2c863c44dfc9beb5d62a1b373e9300e4ec5d4bfa53d994bf00b77b3acb9351977509f50675ecf8403d7ffc19fcaf4a SHA512 ca5ff31a5252f66993f65c54c0806f06221f4705954aff237e7cda9f6ee9794afe579aaa9d8ac8351a73480b392c386dd25ae05321105f7b4f76d0b54129c625
+DIST Remmina-v1.4.41.tar.bz2 2180436 BLAKE2B 08c7d2825deeaa5b6dd5d648e5389d9ea882ef44e409c755d78483f805808563439e6c1d4819f56b7be9b265635bb1db834b219b9519a1c07f766d5f667d0d01 SHA512 0f86fe3f815e60b7627287ffc361c9e57a5cebe8a2dc92887849c7ed5a15c2e0aab9106b1a49fc211f7b256bf65943f4f80c238f03f58a3d7f93cf9cb4769863
--- a/net-misc/remmina/remmina-1.4.41.ebuild
+++ b/net-misc/remmina/remmina-1.4.41.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+MY_P="${PN^}-v${PV}"
+inherit cmake python-single-r1 xdg
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+appindicator crypt cups examples keyring gvnc kwallet nls python spice ssh rdp vnc wayland webkit zeroconf X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} ) || ( X wayland )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[X?,wayland?]
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+	appindicator? ( dev-libs/libayatana-appindicator )
+	crypt? ( dev-libs/libgcrypt:0= )
+	keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet:6 )
+	python? ( ${PYTHON_DEPS} )
+	rdp? ( >=net-misc/freerdp-3.11.0:3=
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4.1 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	spice? ( app-emulation/spice-protocol )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.4.40-kf6wallet.patch" # bug 950750; TODO: upstream
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=ON
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF6WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_PYTHONLIBS=$(usex python ON OFF)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}