sys-libs/libosinfo: bump to 1.8.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

sys-libs/libosinfo/Manifest

@@ -1 +1,2 @@
 DIST libosinfo-1.6.0.tar.gz 1024787 BLAKE2B 4d0783b41f8c9ed7472c798acede0cd1f3808858ab954e838e8d7543dc50a9819d1f26b0cb02a97c8ed8ebee47db1b915aab5daadc0be2742e8f5c1ba8451a75 SHA512 53359095e40ef12e0cc142ddc92119b4a753bb47a728f13a8ff500a19108a44eb1f6ebe4ed67b04347a707dd0c0d55bcfe6815b57d187237dddd7376ebe9cf5e
+DIST libosinfo-1.8.0.tar.xz 273324 BLAKE2B 0d289df4eb1eb0f9793227b7925cfc37e253a4db0da5c420e7b058d4c060ae50a5609bd25f7d07822e0110e535561f675cf8eddbe6bce0875757f10ee30b2c22 SHA512 1d831443af9eea6a5ba1edccafcd47e56fc55e3cc43c0572044abc9c70c4eb8bbe0d95019d42bbdc3b680a2f52511863412ea9587c6eb553353b3802e94b2960

sys-libs/libosinfo/libosinfo-1.8.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit meson udev vala xdg
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="https://libosinfo.org/"
+SRC_URI="https://releases.pagure.org/libosinfo/${P}.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="gtk-doc +introspection +vala test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Unsure about osinfo-db-tools rdep, but at least fedora does it too
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	net-libs/libsoup:2.4
+	>=dev-libs/libxml2-2.6.0
+	>=dev-libs/libxslt-1.0.0
+	sys-apps/hwids[pci,usb]
+	sys-apps/osinfo-db-tools
+	sys-apps/osinfo-db
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+"
+DEPEND="${RDEPEND}"
+# perl dep is for pod2man for automagic manpage building
+BDEPEND="
+	dev-lang/perl
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_feature introspection enable-introspection)
+		$(meson_use test enable-tests)
+		$(meson_feature vala enable-vala)
+		-Dwith-pci-ids-path=/usr/share/misc/usb.ids
+		-Dwith-usb-ids-path=/usr/share/misc/pci.ids
+	)
+	meson_src_configure
+}