mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-10-20 01:17:05 -07:00
Matthew S. Turnbull
c8b723e9a3
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com> Signed-off-by: Joonas Niilola <juippis@gentoo.org>
57 lines
1.1 KiB
Bash
57 lines
1.1 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python3_{10..11} )
|
|
|
|
inherit meson python-r1
|
|
|
|
DESCRIPTION="Python bindings for x11-libs/xapp"
|
|
HOMEPAGE="https://github.com/linuxmint/python3-xapp"
|
|
SRC_URI="https://github.com/linuxmint/python3-xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="LGPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm64 ~loong ~ppc64 ~riscv x86"
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
|
|
DEPEND="
|
|
<x11-libs/xapp-2.8.0[introspection]
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
${PYTHON_DEPS}
|
|
dev-python/psutil[${PYTHON_USEDEP}]
|
|
"
|
|
|
|
src_prepare() {
|
|
echo "option('python', type: 'string', value: 'python3')" >> meson_options.txt || die
|
|
sed -i "s/find_installation('python3')/find_installation(get_option('python'))/" meson.build || die
|
|
default
|
|
}
|
|
|
|
src_configure() {
|
|
configuring() {
|
|
meson_src_configure \
|
|
-Dpython="${EPYTHON}"
|
|
}
|
|
python_foreach_impl configuring
|
|
}
|
|
|
|
src_compile() {
|
|
python_foreach_impl meson_src_compile
|
|
}
|
|
|
|
src_test() {
|
|
python_foreach_impl meson_src_test
|
|
}
|
|
|
|
src_install() {
|
|
installing() {
|
|
meson_src_install
|
|
python_optimize
|
|
}
|
|
python_foreach_impl installing
|
|
}
|