mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 12:58:16 -07:00
68 lines
1.5 KiB
Bash
68 lines
1.5 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{12..14} )
|
|
|
|
inherit distutils-r1 optfeature
|
|
|
|
DESCRIPTION="Policy Analysis Tools for SELinux"
|
|
HOMEPAGE="https://github.com/SELinuxProject/setools/wiki"
|
|
|
|
if [[ ${PV} == *9999* ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/SELinuxProject/setools.git"
|
|
else
|
|
SRC_URI="https://github.com/SELinuxProject/setools/releases/download/${PV}/${P}.tar.bz2"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
|
|
fi
|
|
|
|
LICENSE="GPL-2 LGPL-2.1"
|
|
SLOT="0"
|
|
IUSE="test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
${PYTHON_DEPS}
|
|
>=dev-python/networkx-2.6[${PYTHON_USEDEP}]
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
>=sys-libs/libsepol-3.2:=
|
|
>=sys-libs/libselinux-3.2:=
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
>=dev-python/cython-0.29.14[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/pyqt6[gui,testlib,widgets,${PYTHON_USEDEP}]
|
|
dev-python/pytest-qt[${PYTHON_USEDEP}]
|
|
sys-apps/checkpolicy
|
|
)
|
|
"
|
|
|
|
EPYTEST_IGNORE=(
|
|
# mcp unpackaged
|
|
tests/library/mcp/test_server.py
|
|
)
|
|
EPYTEST_PLUGINS=()
|
|
distutils_enable_tests pytest
|
|
|
|
python_prepare_all() {
|
|
sed -i "s@^lib_dirs = .*@lib_dirs = ['${ESYSROOT}/usr/$(get_libdir)']@" "${S}"/setup.py || \
|
|
die "failed to set lib_dirs"
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
rm -rf setools || die
|
|
epytest
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "apol: graphical SELinux policy analysis tool" \
|
|
"dev-python/pyqt6[gui,widgets]" "dev-python/pygraphviz"
|
|
}
|