dev-libs/json-glib: bump to 1.4.4

Package-Manager: Portage-2.3.49, Repoman-2.3.10

dev-libs/json-glib/Manifest

@@ -1 +1,2 @@
 DIST json-glib-1.2.8.tar.xz 604336 BLAKE2B c85b7dcdb8d409afc1c0261e97e271f5be67a4dbc21d1ac2f6ace656106ca437f3330fda90f5add8371118b0c233f2dcd2bb9b6bc20c6452c1f85a44895eb008 SHA512 85d8ad431363b8698d71684927b8aa38749d99ea7236334ec09fd81482489f1ab9cb12dabcbe13f6b6ffd7e5d70ade47a36b511e275915d4aa858af647db90ba
+DIST json-glib-1.4.4.tar.xz 165584 BLAKE2B 0cdb518cd139b8dbdbf31c9bc00ddedca6385d7132843455a7898f3544fb43b62d6626d49944e83ef10ab9a555cf21c7e4548df7d784bcb4020f4026e0f3045e SHA512 cf56a99dce3938b5c0075810f105719836fac65392da33a49b26ebf33aee1fab89ca9fac58059a2008d688ecc75a3e524de60621a5b027d566963541f38b971f

dev-libs/json-glib/json-glib-1.4.4.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome.org meson multilib-minimal xdg-utils
+
+DESCRIPTION="Library providing GLib serialization and deserialization for the JSON format"
+HOMEPAGE="https://wiki.gnome.org/Projects/JsonGlib"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="gtk-doc +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+"
+# TODO: Can we use a newer docbook-xml-dtd, or is one needed at all?
+DEPEND="${RDEPEND}
+	~app-text/docbook-xml-dtd-4.1.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.20 )
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	xdg_environment_reset
+	default
+	# Disable installed-tests; this also indirectly removes build_aux/gen-installed-test.py calls, thus not needing python-any-r1.eclass
+	sed -e 's/install: true/install: false/g' -i json-glib/tests/meson.build || die
+	sed -e '/install_data/d' -i json-glib/tests/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dintrospection=$(multilib_native_usex introspection true false)
+		-Ddocs=$(multilib_native_usex gtk-doc true false)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_install() {
+	meson_src_install
+}
+
+multilib_src_test() {
+	meson_src_test
+}