x11-libs/libnotify: Version bump to 0.7.9

Signed-off-by: Matt Turner <mattst88@gentoo.org>

x11-libs/libnotify/Manifest

@@ -1 +1,2 @@
 DIST libnotify-0.7.8.tar.xz 108436 BLAKE2B 0a73eabe58faca55e16774cda6f649ab3187bd73a1f87b538d5098f390571a6a34078883dbd2447731d6e4cae315d8286e9e8acc06e85590c8b05a693a83e7f7 SHA512 9973d7a1af5dd7cfbaa0d0d2c9e72a40df9d814967fde47e95763a69690cc4ed32ecf713d75f91f3dff99a693eff9dab963be124e0530ebf231d517a44e75e94
+DIST libnotify-0.7.9.tar.xz 98148 BLAKE2B 4728d00a204cd1003e8171a54c23bb975c0477c245c1175558f27555763113ec8bd7abd7ef81f6bad2b98604efe436d843958e77473436e68560775804473383 SHA512 8a842b50777279efdb7d96a836a546c47decad158a4f03f7ffc818860d1f6276a657619e4f4a19a4e2f5ad55e0371c793420d50d802983700e8c342273b73874

x11-libs/libnotify/libnotify-0.7.9.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson multilib-minimal xdg-utils
+
+DESCRIPTION="A library for sending desktop notifications"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libnotify"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="gtk-doc +introspection test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-eselect/eselect-notify-send
+	>=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}]
+	x11-libs/gdk-pixbuf:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-libs/gobject-introspection-common-1.32
+	dev-util/glib-utils
+	virtual/pkgconfig
+	app-text/docbook-xsl-ns-stylesheets
+	dev-libs/libxslt
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.1.2 )
+	test? ( x11-libs/gtk+:3[${MULTILIB_USEDEP}] )
+"
+PDEPEND="virtual/notification-daemon"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dtests="$(usex test true false)"
+		-Dintrospection="$(multilib_native_usex introspection enabled disabled)"
+		-Dgtk_doc=$(multilib_native_usex gtk-doc true false)
+		-Ddocbook_docs=disabled
+	)
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+
+	mv "${ED}"/usr/bin/{,libnotify-}notify-send || die #379941
+}
+
+pkg_postinst() {
+	eselect notify-send update ifunset
+}
+
+pkg_postrm() {
+	eselect notify-send update ifunset
+}