app-backup/dar: add 2.7.12

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Viorel Munteanu
2023-09-03 18:02:51 +03:00
parent 3a02b1fde3
commit fedfc5cc89
2 changed files with 95 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST dar-2.7.10.tar.gz 2418752 BLAKE2B 31365e900cdcd89c297f78953e82d7288cec524cc3f01a71f659a4e0238797d72c0c629d6fcfad00fa7bdaae1b846d86daa50c7857b13cac0ffac9e98bc398ef SHA512 3b75f06013d13f315280625b3ebf147e833b91164646f271ff81aa0961b788eb12a4dc6a743bbd8de4c7347bad03f2372fd8f5c038d0a83d45f3479cdba4cece
DIST dar-2.7.11.tar.gz 2417878 BLAKE2B 8cb166585d47f13eb796be25746dbfc33dc56f6194fa61ce811c3319354165152af05b4b82931396f886ef65163ffe2c16096aba0f7ecde6cf5a2b8ead75c4eb SHA512 17f19c865e38a4d319d84882cb8db7825cdd0092cd24af6f5a2aa60bc49cad16d51baea0f8148512e3ca6fc3fdd720b1ccd49b33dcafd674dbfa3256d0c7840e
DIST dar-2.7.12.tar.gz 2421683 BLAKE2B 3dc5fc362dbdc47acef33a57c07b21bb2e1cd197bb3475ecf27cf2cb8b54f13a962a386a8e472fc53e3069bbc6acc549e66fadafd1572cbba93eb41f1d493661 SHA512 55b4215da23ca63de479ab34f0d50e4eeb13548891e537702971ec6fc6e6a19e44282a6a711549f468abd507bc1d67f9df08fb76b4b5208c6e8843b3042d5ad2
+94
View File
@@ -0,0 +1,94 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic
DESCRIPTION="A full featured backup tool, aimed for disks"
HOMEPAGE="http://dar.linux.free.fr/"
SRC_URI="https://downloads.sourceforge.net/project/dar/dar/${PV}/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync xattr"
REQUIRED_USE="
?? ( dar32 dar64 )
gpg? ( gcrypt )
"
RESTRICT="test" # need to be run as root
RDEPEND="
app-arch/bzip2:=
app-arch/xz-utils
app-arch/zstd:=
dev-libs/libthreadar
sys-libs/libcap
>=sys-libs/zlib-1.2.3:=
argon2? ( app-crypt/argon2:= )
curl? ( net-misc/curl )
gcrypt? (
dev-libs/libgcrypt:0=
dev-libs/libgpg-error
)
gpg? ( app-crypt/gpgme:= )
lz4? ( app-arch/lz4:= )
lzo? ( dev-libs/lzo:2 )
nls? ( virtual/libintl )
rsync? ( net-libs/librsync:= )
xattr? ( sys-apps/attr )
"
DEPEND="${RDEPEND}"
BDEPEND="
doc? ( app-doc/doxygen )
nls? ( sys-devel/gettext )
"
QA_PKGCONFIG_VERSION="" #862025 - upstream has a different numbering scheme for libdar
src_configure() {
# configure.ac is totally funked up regarding the AC_ARG_ENABLE
# logic.
# For example "--enable-dar-static" causes configure to DISABLE
# static builds of dar.
# Do _not_ use $(use_enable) until you have verified that the
# logic has been fixed by upstream.
local myconf=(
--disable-dar-static
--disable-python-binding
--disable-upx
$(usev !argon2 --disable-libargon2-linking)
$(usev !curl --disable-libcurl-linking)
$(usev dar32 --enable-mode=32)
$(usev dar64 --enable-mode=64)
$(usev !doc --disable-build-html)
$(usev !gcrypt --disable-libgcrypt-linking)
$(usev !gpg --disable-gpgme-linking)
$(usev !lz4 --disable-liblz4-linking)
$(usev !lzo --disable-liblzo2-linking)
$(usev !nls --disable-nls)
$(usev !rsync --disable-librsync-linking)
$(usev !xattr --disable-ea-support)
)
# Bug 103741
filter-flags -fomit-frame-pointer
econf "${myconf[@]}"
}
src_install() {
emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
einstalldocs
find "${ED}" -name "*.la" -delete || die
# Bug 729150
rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
}