net-fs/davfs2: remove questionable USE=split-usr

In bug 884323 it was noted that merged-usr systems get a conflict,
because upstream attempted to install a symlink in /sbin pointing to
/usr/sbin. It was noted in the bug that /sbin isn't needed at all,
despite which the chosen solution was to add IUSE=split-usr and
conditionally create the (useless) symlink.

In version 1.7.0 upstream dropped this entirely, indicating they don't
think it's a terribly good idea either. Take this opportunity to revert
everything and go install exclusively to /usr/sbin, which should have
been the original solution all along.

Bug: https://bugs.gentoo.org/884323
Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

net-fs/davfs2/davfs2-1.6.0-r2.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Linux FUSE (or coda) driver that allows you to mount a WebDAV resource"
+HOMEPAGE="https://savannah.nongnu.org/projects/davfs2"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="nls"
+RESTRICT="test"
+
+RDEPEND="dev-libs/libxml2
+	net-libs/neon
+	sys-libs/zlib
+	nls? ( virtual/libintl virtual/libiconv )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="${RDEPEND}
+	acct-group/davfs2
+	acct-user/davfs2
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.0-neon-0.32-support.patch
+)
+
+src_prepare() {
+	local f
+
+	# Let the package manager handle man page compression
+	while IFS="" read -d $'\0' -r f ; do
+		sed -e '/^manual[58]_DATA/ s/[.]gz//g' -i "${f}" || die
+	done < <(find "${S}"/man -type f -name 'Makefile.in' -print0)
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-largefile $(use_enable nls) ssbindir="${EPREFIX}/usr/sbin"
+}
+
+pkg_postinst() {
+	elog
+	elog "Quick setup:"
+	elog "   (as root)"
+	elog "   # gpasswd -a \${your_user} davfs2"
+	elog "   # echo 'https://path/to/dav /home/\${your_user}/dav davfs rw,user,noauto  0  0' >> /etc/fstab"
+	elog "   (as user)"
+	elog "   \$ mkdir -p ~/dav"
+	elog "   \$ mount ~/dav"
+	elog
+}

net-fs/davfs2/davfs2-1.6.1-r2.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -12,7 +12,7 @@ SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
 LICENSE="GPL-3+"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
-IUSE="nls split-usr"
+IUSE="nls"
 RESTRICT="test"
 
 RDEPEND="dev-libs/libxml2
@@ -39,14 +39,7 @@ src_prepare() {
 }
 
 src_configure() {
-	local ssbindir
-	if use split-usr; then
-		ssbindir=${EPREFIX}/sbin
-	else
-		ssbindir=${EPREFIX}/usr/sbin
-	fi
-
-	econf --enable-largefile $(use_enable nls) ssbindir="${ssbindir}"
+	econf --enable-largefile $(use_enable nls) ssbindir="${EPREFIX}/usr/sbin"
 }
 
 pkg_postinst() {