Merge updates from master

2026-09-21 16:09:05 -07:00 · 2023-07-09 18:16:39 +00:00
parent eea451fa5a 7a2d033e38
commit feb83d0fb4
7 changed files with 171 additions and 5 deletions
--- a/dev-python/PyQt-builder/PyQt-builder-1.15.1.ebuild
+++ b/dev-python/PyQt-builder/PyQt-builder-1.15.1.ebuild
@@ -18,7 +18,7 @@ fi

 LICENSE="|| ( GPL-2 GPL-3 SIP )"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~loong ~ppc ~ppc64 ~riscv x86"
+KEYWORDS="amd64 arm arm64 ~loong ~ppc ppc64 ~riscv x86"

 RDEPEND="
 	dev-python/packaging[${PYTHON_USEDEP}]
--- a/dev-python/jsonschema-specifications/jsonschema-specifications-2023.6.1.ebuild
+++ b/dev-python/jsonschema-specifications/jsonschema-specifications-2023.6.1.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="

 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"

 RDEPEND="
 	>=dev-python/referencing-0.28.0[${PYTHON_USEDEP}]
--- a/dev-python/jsonschema/jsonschema-4.18.0.ebuild
+++ b/dev-python/jsonschema/jsonschema-4.18.0.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="

 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"

 RDEPEND="
 	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
--- a/dev-python/referencing/referencing-0.29.1.ebuild
+++ b/dev-python/referencing/referencing-0.29.1.ebuild
@@ -25,7 +25,7 @@ SRC_URI+="

 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"

 RDEPEND="
 	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
--- a/dev-python/rpds-py/rpds-py-0.8.10.ebuild
+++ b/dev-python/rpds-py/rpds-py-0.8.10.ebuild
@@ -64,7 +64,7 @@ LICENSE+="
 	Unicode-DFS-2016
 "
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"

 BDEPEND="
 	test? (
--- a/net-dns/pdns/Manifest
+++ b/net-dns/pdns/Manifest
@@ -1,3 +1,4 @@
 DIST pdns-4.7.3.tar.bz2 1353333 BLAKE2B 9dc693c940af08755dcf2c77d103bf219e453684f1714eb0790bc06b68ee01872fafc29ab7ba62a8d2cde9dc0035c527d9f241afe7fb170821dfeb5b6c32242d SHA512 25ca5ef04297efc56f6b88e06177d0db5ed390844225dbc53bff6a9299ba3f711aa27642adca31df0f04e6af7059280690a3793458090cd6b2703cbc4fc9072a
 DIST pdns-4.7.4.tar.bz2 1339609 BLAKE2B b5aebad86cf43d87939dcaf1f31cf95969ce3fe5cf55237117eb455c980f6b617ad2d4769d002698b87161a04c5c9e9cefad709cdae703756d6660aef82af6de SHA512 7b666bba72adb2058aa28cff9962bbbf5ddc77860e5f55f74629e2ba27787595347584b7881a846d6c7a698221de785a9dce45992b80313977bbe1e5e5d0d05c
 DIST pdns-4.8.0.tar.bz2 1354234 BLAKE2B 485b168b4fe8ee6dc23004f3382b51fc207f0ffeb8e7924a731a56afccdc1144b7f8fd5b192d229cffc64afbdc261f20228de974ffad6bd74a5149a95b0355c0 SHA512 5984877d392a61d849a83e139384db7834173534239e21ba02e4617d2d908839e497278764c9e9c15b89697a70295fab7ba46c63e06fdbf7d43fff8d29b56944
+DIST pdns-4.8.1.tar.bz2 1345713 BLAKE2B 4f56d67058b17f6b25b28896d1b25554ae84ddd5765b01292b2592d5dbc5746bbc57a1790122e318da4d57c5eb342d0d2df092d8af0fcb977d9dc8d172c6e176 SHA512 56b2995e90db179c89708bafbe8494dd885102c5f40772f7d48f4c5aea4ed6f0bb900c970f62f90f606ab0db995c512de1e6a5af6b546cd4fbbd232085b0e07c
--- a/net-dns/pdns/pdns-4.8.1.ebuild
+++ b/net-dns/pdns/pdns-4.8.1.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit flag-o-matic lua-single python-any-r1
+
+DESCRIPTION="The PowerDNS Daemon"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug doc geoip ldap lmdb lua-records mysql odbc postgres remote sodium sqlite systemd tools tinydns test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+DEPEND="${LUA_DEPS}
+	dev-libs/openssl:=
+	dev-libs/boost:=
+	lmdb? ( >=dev-db/lmdb-0.9.29 )
+	lua-records? ( >=net-misc/curl-7.21.3 )
+	mysql? ( dev-db/mysql-connector-c:= )
+	postgres? ( dev-db/postgresql:= )
+	ldap? ( >=net-nds/openldap-2.0.27-r4:= app-crypt/mit-krb5 )
+	odbc? ( dev-db/unixODBC )
+	sqlite? ( dev-db/sqlite:3 )
+	geoip? ( >=dev-cpp/yaml-cpp-0.5.1:= dev-libs/geoip )
+	sodium? ( dev-libs/libsodium:= )
+	tinydns? ( >=dev-db/tinycdb-0.77 )
+	elibc_glibc? ( x86? ( >=sys-libs/glibc-2.34 ) )"
+RDEPEND="${DEPEND}
+	acct-user/pdns
+	acct-group/pdns"
+
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+	append-lfs-flags
+	append-cppflags -D_TIME_BITS=64
+}
+
+src_configure() {
+	local cnf_dynmodules="bind lua2 pipe" # the default backends, always enabled
+
+	use geoip && cnf_dynmodules+=" geoip"
+	use ldap && cnf_dynmodules+=" ldap"
+	use lmdb && cnf_dynmodules+=" lmdb"
+	use mysql && cnf_dynmodules+=" gmysql"
+	use odbc && cnf_dynmodules+=" godbc"
+	use postgres && cnf_dynmodules+=" gpgsql"
+	use remote && cnf_dynmodules+=" remote"
+	use sqlite && cnf_dynmodules+=" gsqlite3"
+	use tinydns && cnf_dynmodules+=" tinydns"
+
+	econf \
+		--disable-static \
+		--sysconfdir=/etc/powerdns \
+		--libdir=/usr/$(get_libdir)/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-modules= \
+		--with-dynmodules="${cnf_dynmodules}" \
+		--with-mysql-lib=/usr/$(get_libdir) \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable lua-records) \
+		$(use_enable test unit-tests) \
+		$(use_enable tools) \
+		$(use_enable systemd) \
+		$(use_with sodium libsodium) \
+		${myconf}
+}
+
+src_compile() {
+	default
+	use doc && emake -C codedocs codedocs
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/pdns.conf{-dist,}
+
+	fperms 0700 /etc/powerdns
+	fperms 0600 /etc/powerdns/pdns.conf
+
+	# set defaults: setuid=pdns, setgid=pdns
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/g' \
+		"${D}"/etc/powerdns/pdns.conf
+
+	newinitd "${FILESDIR}"/pdns-r1 pdns
+
+	keepdir /var/empty
+
+	if use doc; then
+		docinto html
+		dodoc -r codedocs/html/.
+	fi
+
+	# Install development headers
+	insinto /usr/include/pdns
+	doins pdns/*.hh
+	insinto /usr/include/pdns/backends/gsql
+	doins pdns/backends/gsql/*.hh
+
+	if use ldap ; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/dnsdomain2.schema
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "PowerDNS provides multiple instances support. You can create more instances"
+	elog "by symlinking the pdns init script to another name."
+	elog
+	elog "The name must be in the format pdns.<suffix> and PowerDNS will use the"
+	elog "/etc/powerdns/pdns-<suffix>.conf configuration file instead of the default."
+
+	local old
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 3.2 || continue
+
+		echo
+		ewarn "To fix a security bug (bug #458018) had the following"
+		ewarn "files/directories the world-readable bit removed (if set):"
+		ewarn "  ${EPREFIX}/etc/powerdns"
+		ewarn "  ${EPREFIX}/etc/powerdns/pdns.conf"
+		ewarn "Check if this is correct for your setup"
+		ewarn "This is a one-time change and will not happen on subsequent updates."
+		chmod o-rwx "${EPREFIX}"/etc/powerdns/{,pdns.conf}
+
+		break
+	done
+
+	if use postgres; then
+		for old in ${REPLACING_VERSIONS}; do
+			ver_test ${old} -lt 4.1.11-r1 || continue
+
+			echo
+			ewarn "PowerDNS 4.1.11 contains a security fix for the PostgreSQL backend."
+			ewarn "This security fix needs to be applied manually to the database schema."
+			ewarn "Please refer to the official security advisory for more information:"
+			ewarn
+			ewarn "  https://doc.powerdns.com/authoritative/security-advisories/powerdns-advisory-2019-06.html"
+
+			break
+		done
+	fi
+}