dev-python/flask: Bump to 3.0.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/flask/Manifest

@@ -1 +1,2 @@
 DIST flask-3.0.2.tar.gz 675248 BLAKE2B 137e09ac0f3bb9d027f2c8204769ae98ae5b9992f6126961208a875efb8d450abec471859ab0341120356c9b61238700f0e918da867d7265e31e73cee3a242db SHA512 02f937dae7d654f6286eb9fcf2d68d83f3ef56dbc4d59a961ea1bd95d17fac7a5ace3f27ebb03ff0592f6a87361e59934ffda098714fc8a049a487d4c0bbc0ef
+DIST flask-3.0.3.tar.gz 676315 BLAKE2B 19013ff4588dc057febe2720eadcfcadb0e1854731c2c9e391449696549106da930c11f94782610424ea40c1377e9b8aa52ca39fedc6ad0c98c9a70a56d01514 SHA512 977c0e5fd2d496fae8e34a035f211118642dc6518a14dc5f6c175b72c6a76407aeb9ff0ed1f5db636370a9aa7e0d36baa783713ea7bdabd7f28c8c2b94643cd1

dev-python/flask/flask-3.0.3.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="
+	https://palletsprojects.com/p/flask/
+	https://github.com/pallets/flask/
+	https://pypi.org/project/Flask/
+"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	inherit pypi
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/blinker-1.6.2[${PYTHON_USEDEP}]
+	>=dev-python/click-8.1.3[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-2.1.2[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-3.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/asgiref-3.2[${PYTHON_USEDEP}]
+		!!dev-python/shiboken2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/pallets-sphinx-themes \
+	dev-python/sphinx-issues \
+	dev-python/sphinx-tabs \
+	dev-python/sphinxcontrib-log-cabinet
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}