sci-libs/linux-gpib-modules: Version bump

Bug: https://bugs.gentoo.org/873382
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

sci-libs/linux-gpib-modules/Manifest

@@ -1 +1,2 @@
 DIST linux-gpib-4.3.4.tar.gz 1395770 BLAKE2B 3c7182ac127851ebf0f5416ea639d7f858c160ba00f01aa7f7e423f6fb7b3be5b089424d3a473497562d040c194483ebc93d8a2a0f64582fb8907b42e2c4b832 SHA512 397ad86883bf562b004673ae47218108d392f2a15121c95926ea38764e7a76b382cb199fd48c35c9777f34c8eb99965e3d4ea2028e86ce02bcda4bd23127cbd5
+DIST linux-gpib-4.3.5.tar.gz 1462624 BLAKE2B fff30ed1a7abc18cd4317e8f8979ef4014a532baab8c014f9a2eaa3338a2e8e8b672214d3f2b3f44066be15f432861a3fe3d67652f6966e73e561d99ff1e1566 SHA512 018cc255922a6335f8d28418b0a0808c3a369506470d9c81432ac7183ae255217d938a419e10ba2b0c44205a9d901405ce00ad5bdd968db2721cedd83baa2f76

sci-libs/linux-gpib-modules/linux-gpib-modules-4.3.5.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info linux-mod
+
+DESCRIPTION="Kernel modules for GPIB (IEEE 488.2) hardware"
+HOMEPAGE="https://linux-gpib.sourceforge.io/"
+SRC_URI="mirror://sourceforge/linux-gpib/linux-gpib-${PV}.tar.gz"
+S="${WORKDIR}/linux-gpib-kernel-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug"
+
+COMMONDEPEND=""
+RDEPEND="${COMMONDEPEND}
+	acct-group/gpib
+"
+DEPEND="${COMMONDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	# don't fix debian bugs if they break gentoo
+	"${FILESDIR}/${PN}-4.3.4-depmod.patch"
+)
+
+pkg_setup() {
+	linux-mod_pkg_setup
+
+	if kernel_is -lt 2 6 8; then
+		die "Kernel versions older than 2.6.8 are not supported."
+	fi
+}
+
+src_unpack() {
+	default
+	unpack "${WORKDIR}/linux-gpib-${PV}/linux-gpib-kernel-${PV}.tar.gz"
+}
+
+src_configure() {
+	set_arch_to_kernel
+
+	my_gpib_makeopts=''
+	use debug && my_gpib_makeopts+='GPIB-DEBUG=1 '
+
+	my_gpib_makeopts+="LINUX_SRCDIR=${KERNEL_DIR} "
+}
+
+src_compile() {
+	set_arch_to_kernel
+	emake \
+		${my_gpib_makeopts}
+}
+
+src_install() {
+	set_arch_to_kernel
+	emake \
+		DESTDIR="${ED}" \
+		INSTALL_MOD_PATH="${ED}" \
+		DEPMOD="/bin/true" \
+		docdir="${ED}/usr/share/doc/${PF}/html" \
+		${my_gpib_makeopts} \
+		install
+
+	dodoc ChangeLog AUTHORS README* NEWS
+}