app-crypt/seahorse: Bump to 47.0.1

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/38690
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Guillermo Joandet
2025-01-16 17:51:24 +01:00
committed by Pacho Ramos
parent 021f0c499e
commit fdf55c88b7
2 changed files with 80 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST seahorse-43.0.tar.xz 1392460 BLAKE2B b7ae8b42042ad8e07eaf2633583b566f9757f83bd066eb8b0786d5e89353901f5526ed925bb6152820a5b2a36defb0c0f38dea634c3ae78ebf8d29ab07ff9cfb SHA512 168fdfc829134915f513028b1d35b647aa18a0390786cbf512f7ddb7b125b239f3f3d880a847119a5aa22580354f0b594e553fe3940a3afbda5861e69dd88e5d
DIST seahorse-47.0.1.tar.xz 1401872 BLAKE2B 11b10b1bb1cf4836f7490620169630b71ccf0df67ed25f46e035bb97fbd1450564252cad1974c6e69bfd00019dff8da88875fd605dbcf31bfa64104cb0704e6c SHA512 ac2a20f4d9106f26932c77dc11b4fbd18c8a83d15991f31ae89223a487fa1b4d97cb19de858cc6f53435b7ebcc1dd0f16148d0d1d3080436f0b541de5a56bfcb
+79
View File
@@ -0,0 +1,79 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
DESCRIPTION="Manage your passwords and encryption keys"
HOMEPAGE="https://gitlab.gnome.org/GNOME/seahorse"
LICENSE="GPL-2+ FDL-1.1+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="ldap zeroconf"
RDEPEND="
>=dev-libs/glib-2.66:2
>=app-crypt/gcr-3.38:0=
>=app-crypt/gpgme-1.14.0:=
>=x11-libs/gtk+-3.24.0:3
>=app-crypt/gnupg-2.2
>=gui-libs/libhandy-1.6.0:1
>=app-crypt/libsecret-0.16
dev-libs/libpwquality
virtual/openssh
ldap? ( net-nds/openldap:= )
net-libs/libsoup:3.0
zeroconf? ( >=net-dns/avahi-0.6[dbus] )
"
DEPEND="${RDEPEND}
$(vala_depend)
dev-libs/libxml2:2
app-crypt/gcr:0[vala]
app-crypt/libsecret[vala]
gui-libs/libhandy:1[vala]
"
BDEPEND="
${PYTHON_DEPS}
app-text/docbook-xml-dtd:4.2
app-text/docbook-xsl-stylesheets
dev-libs/appstream-glib
dev-libs/libxslt
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
src_prepare() {
default
vala_setup
gnome2_environment_reset
}
src_configure() {
local emesonargs=(
-Dhelp=true
-Dpgp-support=true
-Dcheck-compatible-gpg=false # keep lowest version listed as compatible as min dep for gnupg RDEPEND
-Dpkcs11-support=true
-Dkeyservers-support=true
-Dhkp-support=true
$(meson_use ldap ldap-support)
$(meson_use zeroconf key-sharing)
-Dmanpage=true
)
meson_src_configure
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}