dev-qt/qtconnectivity: add 6.11.0

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

dev-qt/qtconnectivity/Manifest

@@ -1,3 +1,4 @@
 DIST qtconnectivity-everywhere-src-6.10.1.tar.xz 1058196 BLAKE2B e2f5b95b0d57f9a8307cf9a19e10a7388df36148baad5093030c2b8b8e347c2f36309d93228edd6923be20185dcd2e0081180b56f73708528b9ae742eca0c043 SHA512 a299584e0d1f33517f25f282365ad149244386d0cc9f1196b5e1415017f0f24c8558f79ff2cb8f22c9d8fa98aba0bbed9e93b634ad0a10532288e65836d8d9f7
 DIST qtconnectivity-everywhere-src-6.10.2.tar.xz 1058012 BLAKE2B 485dbea62c8c0fdc4b535d2ac566b67d52423bade67443e94f0770a6630ee3a1aa0d8b122eeb4d4d0ab515bc70435dd05e2c7ed1223e962baddae05161da181f SHA512 f222b713dd5db927c75ecf6ca6ac249272c25894448540d6570c41566a4a33054a744d538f38796776bc7288f63d9a522055169144459f6624281f5e54258e94
 DIST qtconnectivity-everywhere-src-6.11.0-rc.tar.xz 1058332 BLAKE2B 9db86550b62f94581b7973544a265e970807cba4e25f76d803710a412fc59f50aa054b8d84c8a737eedc3f7f05b35e183bfbe4c21e68186972bbf5b29f42e12c SHA512 fe59f791bade94fdc4339476a09736614711cda3f95730428abc1ff5663fdfdf05a00f5656e9005581f35cdf0f734acd082dbcd328617e10cca35fed25baf027
+DIST qtconnectivity-everywhere-src-6.11.0.tar.xz 1058372 BLAKE2B d2718589e36809badee01df38085ca792a95f74a4f09d5a42499f5caf4854f556b0675af7100343097edaecb7383c435cf288bcf68539e6086f2025b46a23d20 SHA512 a0d85d324c503d7ed24631581da14fdd4c71e2b23ae66078149ac736c7131407712a93f901b9caf254f2beb7c698b9d935a9d6f41696757c7a0bd21701c85aee

dev-qt/qtconnectivity/qtconnectivity-6.11.0.ebuild

@@ -0,0 +1,85 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="+bluetooth neard nfc smartcard"
+REQUIRED_USE="
+	|| ( bluetooth nfc )
+	nfc? ( ?? ( neard smartcard ) )
+"
+
+DEPEND="
+	~dev-qt/qtbase-${PV}:6
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus,network]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		neard? ( ~dev-qt/qtbase-${PV}:6[dbus] )
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+RDEPEND="
+	${DEPEND}
+	nfc? (
+		neard? ( net-wireless/neard )
+	)
+"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are auto-skipped, but some still misbehave
+	# if bluez/hardware is available (generally tests here may not be
+	# very relevant without hardware, lists may need to be extended)
+	tst_qbluetoothdevicediscoveryagent #936485
+	tst_qbluetoothlocaldevice
+	tst_qbluetoothserver
+	tst_qbluetoothservicediscoveryagent
+	tst_qbluetoothserviceinfo
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc "
+			$(qt_feature neard)
+			$(qt_feature smartcard pcsclite)
+		")
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}