net-libs/libnma: Version bump to 1.10.6

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29035
Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Guillermo Joandet
2023-01-09 10:42:04 -05:00
committed by Matt Turner
parent 259b2bfd3e
commit fdb3ea53d8
2 changed files with 76 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST libnma-1.10.4.tar.xz 1351932 BLAKE2B 0178407d04fed680b260ea7e4615f0d939483504209b4bc721e2a4fe49ecbf49d9ffde0476b4352973cda9de4f088ac50d557c12f67d970f21031c1741f692e3 SHA512 4fe0d6b0e5b3c1bd7654e03dce747ee390de76d6641eb317fecb901ed6768bf48785e4a99e6fc8f12864066d06a64e308a8dbb2081a2d57e3f1509ca712deccc
DIST libnma-1.10.6.tar.xz 702820 BLAKE2B 8f5b62f9522c8e7f16d6847d0e297d32fa8f62c9be2db68af596765dcfaa93c4eb9c3d3e03098ebd024d7f6ad788dd82eedc7b4841738d4278f64e3a1053d2d6 SHA512 4801db35a8d510c651fc91da4f394a665a4ba5c35fbefe0496363c404b49d5f4e103f49084220ee58b995684d2ac93643320b7d1777ebeea555e7657768a1f6a
+75
View File
@@ -0,0 +1,75 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome.org gnome2-utils meson xdg vala
DESCRIPTION="NetworkManager GUI library"
HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
LICENSE="GPL-2+"
SLOT="0"
# pkcs11 default enabled as it's a small dep often already present by libnma users, and it was default enabled as IUSE=+gcr in nm-applet before
IUSE="gtk-doc +introspection +pkcs11 vala"
REQUIRED_USE="vala? ( introspection )"
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
DEPEND="
>=gui-libs/gtk-4.0:4
app-text/iso-codes
net-misc/mobile-broadband-provider-info
>=dev-libs/glib-2.38:2
>=x11-libs/gtk+-3.12:3[introspection?]
>=net-misc/networkmanager-1.7[introspection?]
pkcs11? ( >=app-crypt/gcr-4.0.0:4 )
introspection? ( >=dev-libs/gobject-introspection-1.56:= )
"
RDEPEND="${DEPEND}
!<gnome-extra/nm-applet-1.16.0" # gschema moved to here before nm-applet-1.16.0
BDEPEND="
dev-libs/libxml2
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc
app-text/docbook-xml-dtd:4.3 )
vala? ( $(vala_depend)
net-misc/networkmanager[vala]
)
"
src_prepare() {
default
use vala && vala_setup
xdg_environment_reset
}
src_configure() {
local emesonargs=(
-Dlibnma_gtk4=true
$(meson_use pkcs11 gcr)
-Dmore_asserts=0
-Diso_codes=true
-Dmobile_broadband_provider_info=true
-Dld_gc=false
$(meson_use gtk-doc gtk_doc)
$(meson_use introspection)
$(meson_use vala vapi)
)
meson_src_configure
}
src_install() {
meson_src_install
rm "${D}/usr/share/glib-2.0/schemas/org.gnome.nm-applet.gschema.xml" || die
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}