app-forensics/zzuf: add 0.15_p20190208, remove 0.15-r1

GitHub snapshot pointing to the latest commit on master. Because there
are two known bugs in 0.15 yet the next version is nowhere in sight.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

app-forensics/zzuf/Manifest

@@ -1 +1,2 @@
 DIST zzuf-0.15.tar.bz2 394859 BLAKE2B a040bc0c43050d36b4dcc59ad49e42a81a0f944fdcaea537a33c925cc9a60cebe46bbd165df4a309204e4c125fb871e9aaaf532183cdb1101ac33230b83f5979 SHA512 7e5b55761c0f75af10920e1ffdde1564022b8d43ce8f59d6b0a27d2c59779ef98dd561cb26f781b8cee09016f08144439770ea2db250874d4bebd2443f592898
+DIST zzuf-0.15_p20190208.tar.gz 140812 BLAKE2B 908661fdb51a5b2d5b188ac7df2731c5f069db8489651145f6d4a5cb0f02dc99fa10c3771a034645043f547ef92dfe9e3cfa3f1442dbad690d88ef620f2cfdd8 SHA512 e4d6b4356385642323520c1f1d476b572465881df539d0c6e7110ca7974da81b4b744896df7deac8b462707ca9e0db578ca0c118d6ba2da4bc78ffe31328f711

app-forensics/zzuf/zzuf-0.15-r1.ebuild

@@ -1,29 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DESCRIPTION="Transparent application input fuzzer"
-HOMEPAGE="http://caca.zoy.org/wiki/zzuf"
-SRC_URI="https://github.com/samhocevar/zzuf/releases/download/v${PV}/${P}.tar.bz2"
-
-LICENSE="WTFPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~sparc ~x86"
-IUSE="static-libs"
-
-# Uses dlopen hack to hijack many libc functions.
-# Fails 2 tests with sandbox enabled: check-zzuf-A-autoinc check-utils
-RESTRICT="test"
-
-DOCS=( AUTHORS COPYING TODO )
-
-src_configure() {
-	econf $(use_enable static-libs static)
-}
-
-src_install() {
-	default
-
-	find "${D}" -name '*.la' -delete || die
-}

app-forensics/zzuf/zzuf-0.15_p20190208.ebuild

@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+EGIT_COMMIT="e598eef77a98d77dc6aec6fd2c845e3cd07dc4fd"
+DESCRIPTION="Transparent application input fuzzer"
+HOMEPAGE="http://caca.zoy.org/wiki/zzuf"
+SRC_URI="https://github.com/samhocevar/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+
+# Uses dlopen hack to hijack many libc functions.
+# Fails 2 tests with sandbox enabled: check-zzuf-A-autoinc check-utils
+RESTRICT="test"
+
+DOCS=( AUTHORS COPYING TODO )
+
+S="${WORKDIR}"/${PN}-${EGIT_COMMIT}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf
+}
+
+multilib_src_install_all() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}