kde-apps/cantor: drop 25.12.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/cantor/Manifest

@@ -1,3 +1,2 @@
 DIST cantor-25.08.3.tar.xz 10918180 BLAKE2B 946ad2599736c94e152deab73b1b99c811d750a317f18f7f3ed6ed64f54bc8bf8ed6e9e8cbc6a2bd6be8a33844e13cb3ef02318ce511796a4bdfbb8f7af928be SHA512 28e1db6e048714a1eabd50f2ff0d21eba808e9833e5a962d9b92be77a64097be0472df2767dc89a40afd7b1e616be06c63ad33b5068c9e041ac7fc6f6933ea5a
-DIST cantor-25.12.0.tar.xz 10919828 BLAKE2B e13aff45b6fc778e41ac079f5111fb43e258eb12e71bb8d0a0e99e286a71eae6396b836dc0f87f5dd1f08c72e51701a69d7bd03dee360a1444c935c6260c123e SHA512 3a9994ca2d8de319dbfb334d2df342a0d61a822d1fa1c605ccc997af22cb6a8516eb71f3da6bfd0bf3203e4c5e8fbced8e1a0859083afe95d806f1519348d296
 DIST cantor-25.12.1.tar.xz 10920516 BLAKE2B 7dc422e04b1ace9671d9d82ad63ccad4fe72eb874c76676c3d8050810300108f78edfd7f4a9c15efd902690523e9832c6946bbe9d7b2f92ab41067c10de29507 SHA512 d284210f41227637a64c8c4d17f3439de505865dcbae5d79bf38fc28b58430db23d66dad71f73f694ae7240d676015d3fbe37ba92e802dca38b752099045327c

kde-apps/cantor/cantor-25.12.0.ebuild

@@ -1,117 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-CMAKE_QA_COMPAT_SKIP=1 # bug 965858
-ECM_HANDBOOK="optional"
-ECM_TEST="forceoptional"
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{11..13} )
-PVCUT=$(ver_cut 1-3)
-KFMIN=6.19.0
-QTMIN=6.9.1
-inherit ecm gear.kde.org lua-single optfeature python-single-r1 xdg
-
-DESCRIPTION="Interface for doing mathematics and scientific computing"
-HOMEPAGE="https://apps.kde.org/cantor/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64 ~arm64"
-IUSE="+analitza julia lua postscript python qalculate R webengine"
-
-REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test"
-
-# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
-DEPEND="
-	>=app-text/poppler-23.12.0[qt6]
-	dev-libs/libxml2:2=
-	dev-libs/libxslt
-	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets,xml]
-	>=dev-qt/qtsvg-${QTMIN}:6
-	>=kde-frameworks/karchive-${KFMIN}:6
-	>=kde-frameworks/kcompletion-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/knewstuff-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/ktexteditor-${KFMIN}:6
-	>=kde-frameworks/ktextwidgets-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
-	analitza? ( >=kde-apps/analitza-${PVCUT}:6 )
-	julia? ( dev-lang/julia )
-	lua? ( ${LUA_DEPS} )
-	qalculate? (
-		sci-libs/cln
-		sci-libs/libqalculate:=
-	)
-	postscript? ( app-text/libspectre )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-qt/qtbase-${QTMIN}:6[dbus]
-	)
-	R? ( dev-lang/R )
-	webengine? (
-		>=dev-qt/qttools-${QTMIN}:6[assistant]
-		>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
-	)
-"
-# !analitza?
-RDEPEND="${DEPEND}
-	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
-		|| (
-			sci-mathematics/maxima
-			sci-mathematics/octave
-		)
-	) ) ) ) ) )
-"
-BDEPEND="x11-misc/shared-mime-info"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-}
-
-src_configure() {
-	use julia && addpredict /proc/self/mem # bug 602894
-
-	local mycmakeargs=(
-		$(cmake_use_find_package analitza Analitza6)
-		$(cmake_use_find_package julia Julia)
-		$(cmake_use_find_package lua LuaJIT)
-		-DUSE_LIBSPECTRE=$(usex postscript)
-		$(cmake_use_find_package python Python3)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package R R)
-		-DENABLE_EMBEDDED_DOCUMENTATION=$(usex webengine)
-	)
-	use lua && mycmakeargs+=(
-		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
-		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
-	)
-	ecm_src_configure
-}
-
-src_compile() {
-	# -j1 for bug #919576
-	MAKEOPTS="-j1" ecm_src_compile
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Maxima backend" sci-mathematics/maxima
-		optfeature "Octave backend" sci-mathematics/octave
-		optfeature "LaTeX support" virtual/latex-base
-	fi
-	xdg_pkg_postinst
-}