app-misc/mosquitto: Drop old versions

Bug: https://bugs.gentoo.org/942139
Signed-off-by: Matt Turner <mattst88@gentoo.org>

app-misc/mosquitto/Manifest

@@ -1,2 +1 @@
-DIST mosquitto-2.0.18.tar.gz 796351 BLAKE2B 6e1d8078ee2813870d79489f312857a12614dc8f1fa3c72269ab29555897ec61d7ba54fcb5e5383f8e852cdb6fffa1d7cb2003ce15da12b986989a6187a186a0 SHA512 63f7e2811964bab5856848e6918627c47afc6534ff60aad5ece3d2fa330b407c9df14027610826e343ee68ff7d8d5d93f2459713061251ded478c42766946767
 DIST mosquitto-2.0.20.tar.gz 799972 BLAKE2B fe1445ff6e2a6869ca911dbc556a2ea3d8826ddfd7dc1c46d6c409a320e58cbae4a3c62f02e3cad96cd2d09d30acd8667e1be2cd197211ca80de2ba782b7c7dc SHA512 4c16ff0ad0e9c6fe5c65ec5a82bef123d9e6490f42658d646e1fad60f098530b7cbbd743460c52d4dec8bc27698c84a557bd539b35ac6c81444539822a544c4c

app-misc/mosquitto/mosquitto-2.0.18.ebuild

@@ -1,134 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{10..12} )
-
-inherit python-any-r1 systemd toolchain-funcs
-
-DESCRIPTION="An Open Source MQTT v3 Broker"
-HOMEPAGE="https://mosquitto.org/ https://github.com/eclipse/mosquitto"
-SRC_URI="https://mosquitto.org/files/source/${P}.tar.gz"
-
-LICENSE="EPL-1.0"
-SLOT="0"
-KEYWORDS="amd64 arm ~arm64 x86"
-IUSE="+bridge examples +persistence +srv ssl systemd tcpd test websockets"
-RESTRICT="!test? ( test )"
-
-REQUIRED_USE="test? ( bridge )"
-
-RDEPEND="
-	acct-user/mosquitto
-	acct-group/mosquitto
-	dev-libs/cJSON
-	srv? ( net-dns/c-ares:= )
-	ssl? (
-		dev-libs/openssl:0=
-	)
-	systemd? ( sys-apps/systemd:= )
-	tcpd? ( sys-apps/tcp-wrappers )
-	websockets? ( net-libs/libwebsockets[lejp] )
-"
-DEPEND="
-	${RDEPEND}
-	test? ( dev-util/cunit )
-"
-BDEPEND="
-	test? (
-		${PYTHON_DEPS}
-		$(python_gen_any_dep 'dev-python/psutil[${PYTHON_USEDEP}]')
-	)
-"
-
-python_check_deps() {
-	python_has_version -b "dev-python/psutil[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use test && python_setup
-}
-
-_emake() {
-	local LIBDIR=$(get_libdir)
-	emake \
-		CC="$(tc-getCC)" \
-		CXX="$(tc-getCXX)" \
-		CLIENT_LDFLAGS="${LDFLAGS}" \
-		LIB_SUFFIX="${LIBDIR:3}" \
-		WITH_BRIDGE="$(usex bridge)" \
-		WITH_PERSISTENCE="$(usex persistence)" \
-		WITH_SRV="$(usex srv)" \
-		WITH_SYSTEMD="$(usex systemd)" \
-		WITH_TLS="$(usex ssl)" \
-		WITH_WEBSOCKETS="$(usex websockets)" \
-		WITH_WRAP="$(usex tcpd)" \
-		"$@"
-}
-
-src_prepare() {
-	default
-	if use persistence; then
-		sed -i -e "/^#autosave_interval/s|^#||" \
-			-e "s|^#persistence false$|persistence true|" \
-			-e "/^#persistence_file/s|^#||" \
-			-e "s|#persistence_location|persistence_location /var/lib/mosquitto/|" \
-			mosquitto.conf || die
-	fi
-
-	# Remove failing tests
-	sed -i \
-		-e '/06-bridge-reconnect-local-out.py/d' \
-		test/broker/Makefile || die
-	sed -i \
-		-e '/02-subscribe-qos1-async2.test/d' \
-		test/lib/Makefile || die
-
-	# Extend test timeout to prevent spurious failures
-	sed -i -e 's/SUB_TIMEOUT=1/SUB_TIMEOUT=3/' \
-		test/client/test.sh || die
-
-	use test && python_fix_shebang test
-}
-
-src_compile() {
-	_emake
-}
-
-src_test() {
-	_emake test
-}
-
-src_install() {
-	_emake DESTDIR="${D}" prefix=/usr install
-	keepdir /var/lib/mosquitto
-	fowners mosquitto:mosquitto /var/lib/mosquitto
-	dodoc README.md CONTRIBUTING.md ChangeLog.txt
-	doinitd "${FILESDIR}"/mosquitto
-	insinto /etc/mosquitto
-	doins mosquitto.conf
-	insinto /usr/share/mosquitto
-	doins misc/letsencrypt/mosquitto-copy.sh
-	systemd_newunit "${FILESDIR}/mosquitto.notify.service" mosquitto.service
-
-	if use examples; then
-		docompress -x "/usr/share/doc/${PF}/examples"
-		dodoc -r examples
-	fi
-}
-
-pkg_postinst() {
-	for v in ${REPLACING_VERSIONS}; do
-		if [[ $(ver_cut 1 "$v") -lt 2 ]]; then
-			elog
-			elog "Please read the migration guide at:"
-			elog "https://mosquitto.org/documentation/migrating-to-2-0/"
-			elog
-			elog "If you use Lets Encrypt TLS certificates, take note of"
-			elog "the changes required to run the daemon as the unprivileged"
-			elog "mosquitto user. The mosquitto-copy.sh script has been"
-			elog "installed to /usr/share/mosquitto/ for your convenience."
-			elog
-		fi
-	done
-}