media-libs/libwmf: add 0.2.15

Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2026-05-06 07:38:44 +01:00
parent e84c5f2ac3
commit fcd2a05228
2 changed files with 82 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST libwmf-0.2.13.tar.gz 3044235 BLAKE2B 0cfbc94d6e7d52c5ecf09b277cf536f56ec54d3b53845e80afdfe4aa3b397562bffd198fb51726d210f21e3e9e16650f85e9188f4e5303b5c4c8b917ef882040 SHA512 f45a936c9bc98fc1a5f2b0808b497119e4dcd3c132615fdddb7583e5719c7d1d7f85c16ebf313cad453e5b7ae3508bf6b80c4ed2b42322b7dec295d8f4eb86ce
DIST libwmf-0.2.15.tar.gz 2766626 BLAKE2B 759702f7a4cfb8821f05dcb50b49b49de3fe2986628e6920181b96c9575e80853c1c82931ca969dbc6c5cde57f2eb6372d14ca0b1338098bd5d7bfb67c575f36 SHA512 e01103356c2ea5f18e418bde6d785811a120300ca6945aa942fecde005cca1dd7c3de1f1d48aa5e24853f1a7d8f21c523e42c55cb5d645f2fe052217ef2b89a6
+81
View File
@@ -0,0 +1,81 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome2-utils
DESCRIPTION="Library for reading vector images in Microsoft's Windows Metafile Format (WMF)"
HOMEPAGE="
https://github.com/caolanm/libwmf
https://wvware.sourceforge.net/
"
SRC_URI="https://github.com/caolanm/libwmf/releases/download/v${PV}/${P}.tar.gz"
LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
IUSE="debug doc expat X"
RDEPEND="
app-text/ghostscript-gpl
media-fonts/urw-fonts
media-libs/freetype:2=
media-libs/libpng:=
media-libs/libjpeg-turbo
virtual/zlib:=
x11-libs/gdk-pixbuf:2
expat? ( dev-libs/expat )
!expat? ( dev-libs/libxml2:2= )
X? (
x11-libs/libX11
x11-libs/libXt
x11-libs/libXpm
)
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
DOCS=( AUTHORS BUILDING ChangeLog CREDITS INSTALL NEWS README TODO )
PATCHES=(
"${FILESDIR}"/${PN}-0.2.8.4-libpng-1.5.patch
"${FILESDIR}"/${PN}-0.2.8.4-pngfix.patch
)
src_configure() {
# Support for GD is disabled, since it's never linked, even, when enabled
# See https://bugs.gentoo.org/268161
local myeconfargs=(
--disable-gd
--disable-static
$(use_enable debug)
$(use_with expat)
$(use_with !expat libxml2)
$(use_with X x)
--with-fontdir="${EPREFIX}"/usr/share/fonts/urw-fonts
--with-freetype
--with-gsfontdir="${EPREFIX}"/usr/share/fonts/urw-fonts
--with-gsfontmap="${EPREFIX}"/usr/share/ghostscript/9.21/Resource/Init/Fontmap
--with-jpeg
--with-layers
--with-png
--with-sys-gd
--with-zlib
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
gnome2_gdk_pixbuf_update
}
pkg_postrm() {
gnome2_gdk_pixbuf_update
}