mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
kde-frameworks/purpose: 5.81.0 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST purpose-5.77.0.tar.xz 158016 BLAKE2B 51e26b284bbeb8ac07690f4b9c571f58b89c977e87a5bdad8f56a5aaacb69b2d1130b08169fcdc7848925b1811d4e632e4c3e9c453e30482a4ed80c4d329c81f SHA512 61261ae4d5ae2327100629ace3e6b2cade9b2894bb21e817700a1265c5283b13a6f828bec47dfd8efa118fadad0f5cc89cbf8fd3e637497dd68345eefaa53956
|
||||
DIST purpose-5.80.0.tar.xz 159308 BLAKE2B e7467c3ca5a39c2482c470aa55debbb29b3e0457271a9f126e4b68dc1c48db245bb1d7adb73fdff6f3bdd044fb99557bc08cf2a72de5cab998dd7a9485002641 SHA512 3746e66f0587ad0b7f62f0c262879a6f2f8a58af3753f6c4a1f28ca4996fa40ad63accb5d024fbef1269b137b45c38234cde0bfc5a046cf1c66b61064a7809b4
|
||||
DIST purpose-5.81.0.tar.xz 159704 BLAKE2B 58893667a268012df7448d0fb5fc1928d5b3aeb61f9839b98a72243b35f1cf9e4f70a6f7db351db3be2bc1b097519fc488caa340b55847bf3536b50bde187b59 SHA512 55ae8014313d8fba6980ee02bc1ba729eb2155e824f333df5b06aeb31320b424db4d79feb0bdbc0a513a7ec59dee6a126ed1234059756d213124fbe1c5245a95
|
||||
|
||||
@@ -0,0 +1,68 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
ECM_QTHELP="false"
|
||||
ECM_TEST="forceoptional"
|
||||
PVCUT=$(ver_cut 1-2)
|
||||
QTMIN=5.15.2
|
||||
inherit ecm kde.org optfeature xdg-utils
|
||||
|
||||
DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
|
||||
LICENSE="LGPL-2.1+"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
|
||||
IUSE="bluetooth +kaccounts"
|
||||
|
||||
# requires running environment
|
||||
RESTRICT+=" test"
|
||||
|
||||
DEPEND="
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtnetwork-${QTMIN}:5
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
=kde-frameworks/kcoreaddons-${PVCUT}*:5
|
||||
=kde-frameworks/ki18n-${PVCUT}*:5
|
||||
=kde-frameworks/kio-${PVCUT}*:5
|
||||
=kde-frameworks/kirigami-${PVCUT}*:5
|
||||
=kde-frameworks/knotifications-${PVCUT}*:5
|
||||
kaccounts? (
|
||||
>=kde-apps/kaccounts-integration-19.04.3:5
|
||||
net-libs/accounts-qt
|
||||
)
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
>=dev-qt/qtquickcontrols-${QTMIN}:5
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
>=kde-frameworks/kdeclarative-${PVCUT}:5
|
||||
bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
|
||||
kaccounts? ( net-libs/accounts-qml )
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
ecm_src_prepare
|
||||
|
||||
use bluetooth ||
|
||||
cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
$(cmake_use_find_package kaccounts KAccounts)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ -z "${REPLACING_VERSIONS}" ]]; then
|
||||
optfeature "Send through KDE Connect" kde-misc/kdeconnect
|
||||
fi
|
||||
ecm_pkg_postinst
|
||||
xdg_icon_cache_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_icon_cache_update
|
||||
}
|
||||
Reference in New Issue
Block a user