sci-geosciences/merkaartor: 0.18.4 version bump

Closes: https://bugs.gentoo.org/716894
Package-Manager: Portage-2.3.98, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-geosciences/merkaartor/Manifest

@@ -1 +1,2 @@
 DIST merkaartor-0.18.3.tar.gz 7104234 BLAKE2B e7d84297452ad20daf2ab18c4aef3736758d98e6f839be1152651aa0196ccee2983d89935f121d4436245d7fdd1fa6b97cd99e6a154158cad4751eba02819a74 SHA512 b34087e0317c196b59dd1de57778b9293d23e4530bd5734661dc2ce53eef85317f512ee446056e045aa8a06146bd029d6274fa5a6f68128db27795d44f0ef915
+DIST merkaartor-0.18.4.tar.gz 6562065 BLAKE2B 2dbd85c81f337138b249807dcb404b9167cc63bec51cc19afa95b088733375bec234df75fef2652864c811ff6d9927c93f16df42044be3706b68332fcd817706 SHA512 16001688584fd13eb7573159092a21ed0189ae0ce900474bacd5b1e47b8cebb0c4b2bd5b904e13a0029ec01167b68a32a9936914b3f5a1360b389aa31858cf9c

sci-geosciences/merkaartor/merkaartor-0.18.3-r4.ebuild

@@ -32,7 +32,7 @@ DEPEND="
 	sci-libs/proj
 	sys-libs/zlib
 	exif? ( media-gfx/exiv2:= )
-	gps? ( >=sci-geosciences/gpsd-3.17-r2 )
+	gps? ( >=sci-geosciences/gpsd-3.17-r2:= )
 	libproxy? ( net-libs/libproxy )
 	webengine? ( dev-qt/qtwebengine:5[widgets] )
 "

sci-geosciences/merkaartor/merkaartor-0.18.4.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="ar cs de en es et fr hr hu id_ID it ja nl pl pt_BR pt ru sk sv uk vi zh_CN zh_TW"
+inherit flag-o-matic l10n qmake-utils xdg-utils
+
+DESCRIPTION="Qt based map editor for the openstreetmap.org project"
+HOMEPAGE="http://www.merkaartor.be https://github.com/openstreetmap/merkaartor"
+SRC_URI="https://github.com/openstreetmap/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug exif gps libproxy webengine"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsingleapplication[X,qt5(+)]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sci-libs/gdal:=
+	sci-libs/proj:=
+	sys-libs/zlib
+	exif? ( media-gfx/exiv2:= )
+	gps? ( >=sci-geosciences/gpsd-3.17-r2 )
+	libproxy? ( net-libs/libproxy )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.18.3-sharedir-pluginsdir.patch ) # bug 621826
+
+DOCS=( AUTHORS CHANGELOG )
+
+src_prepare() {
+	default
+
+	rm -r 3rdparty || die "Failed to remove bundled libs"
+
+	my_rm_loc() {
+		sed -i -e "s:../translations/${PN}_${1}.\(ts\|qm\)::" src/src.pro || die
+		rm "translations/${PN}_${1}.ts" || die
+	}
+
+	if [[ -n "$(l10n_get_locales)" ]]; then
+		l10n_for_each_disabled_locale_do my_rm_loc
+		$(qt5_get_bindir)/lrelease src/src.pro || die
+	fi
+
+	# build system expects to be building from git
+	sed -i src/Config.pri -e "s:SION = .*:SION = \"${PV}\":g" || die
+}
+
+src_configure() {
+	append-cppflags -DACCEPT_USE_OF_DEPRECATED_PROJ_API_H
+
+	# TRANSDIR_SYSTEM is for bug #385671
+	eqmake5 \
+		PREFIX="${ED}/usr" \
+		LIBDIR="${ED}/usr/$(get_libdir)" \
+		PLUGINS_DIR="/usr/$(get_libdir)/${PN}/plugins" \
+		SHARE_DIR_PATH="/usr/share/${PN}" \
+		TRANSDIR_MERKAARTOR="${ED}/usr/share/${PN}/translations" \
+		TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt5/translations" \
+		SYSTEM_QTSA=1 \
+		RELEASE=1 \
+		NODEBUG=$(usex debug 0 1) \
+		GEOIMAGE=$(usex exif 1 0) \
+		GPSDLIB=$(usex gps 1 0) \
+		LIBPROXY=$(usex libproxy 1 0) \
+		USEWEBENGINE=$(usex webengine 1 0) \
+		Merkaartor.pro
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}