app-accessibility/orca: bump to 3.36.5, enable py3.8

Package-Manager: Portage-2.3.103, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

app-accessibility/orca/Manifest

@@ -1 +1,2 @@
 DIST orca-3.34.2.tar.xz 3509556 BLAKE2B 4e73517660b837cec6d4dc12e3b2e57dec526f22aa407ababee2cb12c3aa8807184649b6962f26551926b1b3f8c49230054b4ef5583e15eeeb94685aaaf3ca13 SHA512 b685bd8e417d74ccc0d0ce6b15b3220e5079320198886f568147480f107f7d0273cbd412fdc2c6cc509d3210b36c40aecb50e167d43120f6770ce02a0891ad20
+DIST orca-3.36.5.tar.xz 3578288 BLAKE2B d9711720b7a104bc86c97f1821566dd710f0bd318a5409fc5bd5624e7f35a81e9cd0a3d9fd1337c58b09d1ed8fe1c9eeb5b0822e45f7a711a44405bcb8f54db6 SHA512 87756ab5ea962c715f1a00ba80a30cf2e812bab87cf6f13b437b45b39bb763b684fe69b8847a3ed543c398f79a4d2d3ed33b61f88414f432b473c0892453a4f0

app-accessibility/orca/orca-3.36.5.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-atk-2.34:2
+	>=app-accessibility/at-spi2-core-2.36:2[introspection]
+	>=dev-libs/atk-2.36
+	>=dev-libs/glib-2.28:2
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/gst-python:1.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygobject-3.18:3[${PYTHON_MULTI_USEDEP}]
+	')
+	braille? (
+		$(python_gen_cond_dep '
+			>=app-accessibility/brltty-5.0-r3[python,${PYTHON_MULTI_USEDEP}]
+			dev-libs/liblouis[python,${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-libs/atk[introspection]
+	$(python_gen_cond_dep '
+		>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pyatspi-2.36[${PYTHON_MULTI_USEDEP}]
+		dev-python/setproctitle[${PYTHON_MULTI_USEDEP}]
+	')
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_install() {
+	gnome2_src_install
+	python_optimize
+}