kde-apps/kdenlive: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2020-12-12 18:57:26 +01:00
parent 95cb6035f4
commit fc0cd202a6
2 changed files with 91 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST kdenlive-20.08.3.tar.xz 11383252 BLAKE2B aa8075758ec4b967c8eeabbab611278130df7235f10186b5bc4142a06805fb2cae94806059edf62f9af86a3640cee734863316e7651f3c67d020da32ab0d63ff SHA512 ed3ccffbe7c56d54e3c490d818a504bc4a3d65fd81c4d816a549d2a7d436b5320497145d122f352066def23c43aed523e2d31eb2a2f50378fb0122a89a23c424
DIST kdenlive-20.12.0.tar.xz 11473068 BLAKE2B e24ef0bc04d9ca0ea7e0589f5902fc8f3f2308395cdd5ff1fdc9b8a03f7cda9f28c19ae463020e39c8cc14baac65ccb69d70bc938dff8086b34afedb83b97338 SHA512 eb3f543eea320e4a687a4cbcc1259f96e915166bb222efca41b1111ed67c684e1f598a5344e31903155a4a6602befe316742ce6d16db4966212de8727e09a68e
+90
View File
@@ -0,0 +1,90 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="optional"
ECM_TEST="true"
KFMIN=5.75.0
QTMIN=5.15.1
VIRTUALX_REQUIRED="test"
inherit ecm kde.org
DESCRIPTION="Non-linear video editing suite by KDE"
HOMEPAGE="https://kdenlive.org/en/"
LICENSE="GPL-2"
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
IUSE="gles2-only semantic-desktop share v4l webengine"
BDEPEND="
sys-devel/gettext
"
DEPEND="
dev-cpp/rttr
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
>=dev-qt/qtmultimedia-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/karchive-${KFMIN}:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kdeclarative-${KFMIN}:5
>=kde-frameworks/kguiaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=media-libs/mlt-6.20.0[ffmpeg,frei0r,kdenlive(+),melt(+),qt5,sdl,xml]
semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:5 )
share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
v4l? ( media-libs/libv4l )
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
"
RDEPEND="${DEPEND}
>=dev-qt/qtquickcontrols-${QTMIN}:5
media-video/ffmpeg[encode,sdl,X]
"
RESTRICT+=" test" # segfaults, bug 684132
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package semantic-desktop KF5FileMetaData)
$(cmake_use_find_package share KF5Purpose)
$(cmake_use_find_package v4l LibV4L2)
$(cmake_use_find_package webengine Qt5WebEngineWidgets)
)
ecm_src_configure
}
pkg_postinst() {
ecm_pkg_postinst
# Gentoo bug 603168
if ! has_version "media-libs/mlt[fftw]" ; then
elog "For 'Crop and Transform/Rotate and Shear' effect, please build media-libs/mlt with USE=fftw enabled."
fi
}