dev-python/jaraco-vcs: New package, v2.1.0

New NIH dependency for dev-python/rst-linker.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/jaraco-vcs/Manifest

@@ -0,0 +1 @@
+DIST jaraco_vcs-2.1.0.tar.gz 16434 BLAKE2B 96ca37435b5fdd9bc5e7825ba21ff1aa70285885724bfa9bcbdc21531c15d9952336b888846d2e3200e619ee40da68741cc83205e81925f2a8d9b7a833f0fc8c SHA512 72d1a4ee5c29cdd8122a39c856ec9f910fb4d4ffc0d88f1e9c99723f5a076e1166aed842ba54286b8f14b41cb4c570cd7a9862a33fe7f15cdf637a114f4147ae

dev-python/jaraco-vcs/jaraco-vcs-2.1.0.ebuild

@@ -0,0 +1,44 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Facilities for working with VCS repositories"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.vcs/
+	https://pypi.org/project/jaraco.vcs/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/jaraco-versioning[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jaraco-path[${PYTHON_USEDEP}]
+		dev-vcs/git
+		!sparc? (
+			dev-vcs/mercurial
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# assumes running inside the git repo
+	jaraco/vcs/__init__.py::jaraco.vcs
+)

dev-python/jaraco-vcs/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">jaraco/jaraco.vcs</remote-id>
+		<remote-id type="pypi">jaraco.vcs</remote-id>
+	</upstream>
+</pkgmetadata>