mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
dev-python/sphinx: add 4.3.2
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin
@@ -1,2 +1,3 @@
|
||||
DIST Sphinx-3.5.4.tar.gz 5911093 BLAKE2B 8740714dfaf3733bf57d0b277315b4e7b5cad86247ea30dcbc4f5dadf5f5169329050b7be43ec8625c47df9dcc19afcc6c4d782725c7007f8178b7eb7be7dc05 SHA512 853379f3b0496772846be9beb072c2c8a69ff899ffe4c6435b448ea639a32138c61403f9c14f62f4f78b2e526a2ee7c05b4196eabdeee37bcae6aa98df992125
|
||||
DIST Sphinx-4.3.1.tar.gz 6655951 BLAKE2B eacc9d39e1a108dba1f8d3bd96d7f78f1755f23233c8068dbe598f3d3539d9cf0ea9c12374e0ffc4f471004bbe7cbd6e80ebfa7bcfbf85e5d8c34ed4adfb2acb SHA512 0b7ceb369783d30685c10783fe10b58e92a2f5ae50dda1b6cfb021b0d33fb424a2c6cddc6b97018b63347127fc74ed4f7a442c312ce9e75ceb537f127a46bb9d
|
||||
DIST Sphinx-4.3.2.tar.gz 6657148 BLAKE2B 952cecc20e3f7e046c3ae2abc8524091af82f7947f889320deab3ec82947f793d4dab86ae47f117c84ecdb2e4e50fe531469dffca2806c45500a06c7322bb11b SHA512 2045e1964aef54826a2cde30e6c09b7ec35d49a45b7e449c07ee107c41304435eb51e2be307af77bed4ec50534e6e4009501d58187baa1a129134b69cdc56dff
|
||||
|
||||
129
dev-python/sphinx/sphinx-4.3.2.ebuild
Normal file
129
dev-python/sphinx/sphinx-4.3.2.ebuild
Normal file
@@ -0,0 +1,129 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_SETUPTOOLS=rdepend
|
||||
PYTHON_COMPAT=( python3_{8..10} pypy3 )
|
||||
PYTHON_REQ_USE="threads(+)"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
DESCRIPTION="Python documentation generator"
|
||||
HOMEPAGE="https://www.sphinx-doc.org/
|
||||
https://github.com/sphinx-doc/sphinx"
|
||||
SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
|
||||
S=${WORKDIR}/${P^}
|
||||
|
||||
LICENSE="BSD"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
|
||||
IUSE="doc latex"
|
||||
|
||||
RDEPEND="
|
||||
<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
|
||||
>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
|
||||
<dev-python/docutils-0.18[${PYTHON_USEDEP}]
|
||||
dev-python/imagesize[${PYTHON_USEDEP}]
|
||||
>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
|
||||
>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
|
||||
dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
|
||||
dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
|
||||
dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
|
||||
>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
|
||||
dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
|
||||
dev-python/packaging[${PYTHON_USEDEP}]
|
||||
latex? (
|
||||
dev-texlive/texlive-latexextra
|
||||
dev-texlive/texlive-luatex
|
||||
app-text/dvipng
|
||||
)"
|
||||
BDEPEND="
|
||||
doc? (
|
||||
dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
|
||||
media-gfx/graphviz
|
||||
)
|
||||
test? (
|
||||
dev-python/html5lib[${PYTHON_USEDEP}]
|
||||
virtual/imagemagick-tools[jpeg,png,svg]
|
||||
dev-texlive/texlive-fontsextra
|
||||
dev-texlive/texlive-latexextra
|
||||
dev-texlive/texlive-luatex
|
||||
app-text/dvipng
|
||||
)"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-3.2.1-doc-link.patch"
|
||||
)
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
python_prepare_all() {
|
||||
# disable internet access
|
||||
sed -i -e 's:^intersphinx_mapping:disabled_&:' \
|
||||
doc/conf.py || die
|
||||
|
||||
# remove unnecessary upper bounds
|
||||
sed -e '/Jinja2/s:,<3.0::' \
|
||||
-e '/MarkupSafe/s:<2.0::' \
|
||||
-i setup.py || die
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_compile() {
|
||||
distutils-r1_python_compile
|
||||
|
||||
# Generate the grammar. It will be caught by install somehow.
|
||||
# Note that the tests usually do it for us. However, I don't want
|
||||
# to trust USE=test really running all the tests, especially
|
||||
# with FEATURES=test-fail-continue.
|
||||
pushd "${BUILD_DIR}"/lib >/dev/null || die
|
||||
"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
|
||||
popd >/dev/null || die
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
if use doc; then
|
||||
esetup.py build_sphinx
|
||||
HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
|
||||
fi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
|
||||
local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
|
||||
|
||||
local deselect=(
|
||||
# these tests require Internet access
|
||||
tests/test_build_latex.py::test_latex_images
|
||||
tests/test_build_linkcheck.py::test_defaults
|
||||
tests/test_build_linkcheck.py::test_defaults_json
|
||||
tests/test_build_linkcheck.py::test_anchors_ignored
|
||||
)
|
||||
[[ ${EPYTHON} == pypy3 ]] && deselect+=(
|
||||
tests/test_build_linkcheck.py::test_connect_to_selfsigned_fails
|
||||
tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
|
||||
tests/test_ext_autodoc.py::test_autodoc_typed_inherited_instance_variables
|
||||
tests/test_ext_autodoc.py::test_autodoc_typed_instance_variables
|
||||
tests/test_ext_autodoc.py::test_automethod_for_builtin
|
||||
tests/test_ext_autodoc.py::test_cython
|
||||
tests/test_ext_autodoc.py::test_partialfunction
|
||||
tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
|
||||
tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
|
||||
tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
|
||||
tests/test_ext_autodoc_autodata.py::test_autodata_type_comment
|
||||
tests/test_ext_autodoc_autofunction.py::test_builtin_function
|
||||
tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
|
||||
tests/test_ext_autodoc_configs.py::test_autodoc_type_aliases
|
||||
tests/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
|
||||
tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
|
||||
tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
|
||||
tests/test_pycode_parser.py::test_annotated_assignment
|
||||
)
|
||||
|
||||
epytest ${deselect[@]/#/--deselect }
|
||||
}
|
||||
Reference in New Issue
Block a user