dev-util/bcc-0.18.0: Version bump

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

dev-util/bcc/Manifest

@@ -1,2 +1,3 @@
 DIST bcc-0.16.0.tar.gz 4124285 BLAKE2B 443077ffd5ad02e34d28a86ee64b8ec52fa4a18696295d58e87aaf2aeb833c394047cd0d87b3bf1da52d5512b889f8873b788e8141bdd91c9463e27cf30a1ef6 SHA512 50d09d6d02335a63d7c01c22f16a706584f231ee16973a80df5b640c31b8e25775da13a2bdff9e57c04c7f6181bb8c46cf3bd11c1e59741234024da71c7f6cdb
 DIST bcc-0.17.0.tar.gz 4166410 BLAKE2B 6833c7a58ed9e99b58bf147dc499ba7c7c113961ff5c21a3ac388abab8caa01dc2a67378899e26050460c4af851a5ddd8747911bda7c7b405dfcb6df29981f85 SHA512 32f27bdd3d8f3e850e59011bcf662b91842b1dcef94d118a0662ffda3b2c48c97a359d736d01f6d06afd74e3d7a4efda4966c71a5c9146b2076d4fba087a85cf
+DIST bcc-0.18.0.tar.gz 4171881 BLAKE2B c5bdf70965e16f0391306b004b4f51b370e7de3d061c8c318f25de478bdcb0c4dc083ceb00e19a66115e31e4c3da63e3b5dded750d44d56985f18bf87eb7617e SHA512 9d3e4c60c6415d40fe803bab44d4372028c210a084e3bff87a71771f06810bbafebe10760aedce9fff704c51235f71ff20458942fc1e67d0b83988ce57cfc493

dev-util/bcc/bcc-0.18.0.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit cmake linux-info llvm python-r1
+
+DESCRIPTION="Tools for BPF-based Linux IO analysis, networking, monitoring, and more"
+HOMEPAGE="https://iovisor.github.io/bcc/"
+
+SRC_URI="https://github.com/iovisor/bcc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+luajit test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	>=dev-libs/libbpf-0.3[static-libs(-)]
+	>=sys-kernel/linux-headers-4.14
+	>=dev-libs/elfutils-0.166:=
+	<=sys-devel/clang-12:=
+	<=sys-devel/llvm-12:=[llvm_targets_BPF(+)]
+	luajit? ( dev-lang/luajit )
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}
+	test? (
+		|| (
+			net-misc/iputils[arping]
+			net-analyzer/arping
+		)
+		net-analyzer/netperf
+		net-misc/iperf:*
+	)
+"
+BDEPEND="
+	dev-util/cmake
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/bcc-0.9.0-no-luajit-automagic-dep.patch"
+	"${FILESDIR}/bcc-0.14.0-cmakelists.patch"
+)
+
+# tests need root access
+RESTRICT="test"
+
+pkg_pretend() {
+	local CONFIG_CHECK="~BPF ~BPF_SYSCALL ~NET_CLS_BPF ~NET_ACT_BPF
+		~HAVE_EBPF_JIT ~BPF_EVENTS ~DEBUG_INFO ~FUNCTION_TRACER ~KALLSYMS_ALL
+		~KPROBES"
+
+	check_extra_config
+}
+
+pkg_setup() {
+	LLVM_MAX_SLOT=11 llvm_pkg_setup
+	python_setup
+}
+
+src_prepare() {
+	local bpf_link_path
+
+	# this avoids bundling
+	bpf_link_path="$(realpath --relative-to="${S}/src/cc/libbpf" /usr/include/bpf)" || die
+	ln -sfn "${bpf_link_path}" src/cc/libbpf/include || die
+
+	cmake_src_prepare
+}
+
+python_add_impl() {
+	bcc_python_impls+="${EPYTHON};"
+}
+
+src_configure() {
+	local bcc_python_impls
+	python_foreach_impl python_add_impl
+
+	local -a mycmakeargs=(
+		-DREVISION=${PV%%_*}
+		-DENABLE_LLVM_SHARED=ON
+		-DCMAKE_USE_LIBBPF_PACKAGE=ON
+		-DKERNEL_INCLUDE_DIRS="${KERNEL_DIR}"
+		-DPYTHON_CMD="${bcc_python_impls%;}"
+		$(usex luajit '-DWITH_LUAJIT=1')
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_replicate_script $(grep -Flr '#!/usr/bin/python' "${ED}/usr/share/bcc/tools")
+	python_foreach_impl python_optimize
+
+	newenvd "${FILESDIR}"/60bcc.env 60bcc.env
+}