dev-util/shards: bump up to 0.14.1

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

dev-util/shards/Manifest

@@ -1,2 +1,3 @@
 DIST crystal-molinillo-0.1.0.tar.gz 23932 BLAKE2B c9bcd707a3208f5d80e6e3030523d50f86cb5977799de8ea6035d014094e3c2fff9bb189fa98f566e72e1e7ad161e47e44c89d9b264d47f109b2e891ecb469e5 SHA512 8d74d95896cd7ff510c87e2ffba6ae5f04ceeddde574930ee609851312b65d713a315cc24f9aa3fab02f9447ccb25ef2dd2e8179640b8c5cfb3d7d6b52d1ded5
 DIST shards-0.14.0.tar.gz 61662 BLAKE2B f590b8eb876cb7a5d5bbade13b3ee78db443ef24f9abefe9ba662a7018ee0e543950e84ef388bd3cf81960883a60de4eb2409616790c0caef6d06f8fa19ff288 SHA512 214f038f3ddedca8297fe6deac1d12a632b7563c5eda796771f925abe7f197c637328eb1fd1fdd51063131e51fcc73edd6be59c9b213779b6ed5090e8a715fe6
+DIST shards-0.14.1.tar.gz 61664 BLAKE2B 35f5626096266a86561f9b8613cfdb5f628e2ce247eb511dc0896c600619dcc7660b5b2b473fa0d9cec07010a5e13b8614fa63475acffe17a79cab8503cc6485 SHA512 be51e6d5459f0537681bea9b5c7ff048c33cd67fbb9effa20e6af8ac31f8ee0534f2012ed03712b5204451e7a48b932b0c44011dd39a7b47f81c85587579fcdf

dev-util/shards/shards-0.14.1.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multiprocessing toolchain-funcs
+
+CRYSTAL_MOLINILLO_PV=0.1.0
+CRYSTAL_MOLINILLO_P=crystal-molinillo-${CRYSTAL_MOLINILLO_PV}
+
+DESCRIPTION="Dependency manager for the Crystal language"
+HOMEPAGE="https://github.com/crystal-lang/shards"
+SRC_URI="
+	https://github.com/crystal-lang/shards/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/crystal-lang/crystal-molinillo/archive/v${CRYSTAL_MOLINILLO_PV}.tar.gz -> ${CRYSTAL_MOLINILLO_P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>dev-lang/crystal-0.11.1[yaml]
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT=test # missing files in tarball
+
+src_prepare() {
+	default
+
+	# bundle crystal-molinillo to bootstrap 'shards'
+	mkdir -p lib || die
+	ln -s ../../${CRYSTAL_MOLINILLO_P} lib/molinillo || die
+
+	tc-export CC
+}
+
+src_compile() {
+	emake release=1 FLAGS="--link-flags=\"${LDFLAGS}\" --verbose --threads $(makeopts_jobs)"
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc README.md
+}