gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

app-forensics/chkrootkit: add 0.57

Browse Source 
Closes: https://bugs.gentoo.org/891387
Signed-off-by: Martin Dummer <martin.dummer@gmx.net>
Closes: https://github.com/gentoo/gentoo/pull/29672
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
This commit is contained in:
Martin Dummer
2023-02-19 22:04:34 +01:00
committed by Alfredo Tupone
parent 5fbe68d90e
commit fab60edcf9
2 changed files with 72 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
app-forensics/chkrootkit/Manifest
View File

@@ -2,3 +2,5 @@ DIST chkrootkit-0.54-gentoo.diff.xz 4848 BLAKE2B 25d1736bb839533fae36550518b311e
DIST chkrootkit-0.54.tar.gz 41461 BLAKE2B 61384fda7db08ca2a52ab060ee4ea3edb7311cb9908599a511459dac22340f28e75d732b10d827aaeed89a1ecb6fc7f69ab8fef970aae5a73bae8c7949944831 SHA512 fe8955ac33abaabf304f5580b6f12929f8bf02329ab442380eaa6298440cf1cb0eee2db8e5667ea7d78b89ee2bceb82c10ebb732a71d6bcdda9400569cd587fd
DIST chkrootkit-0.55-gentoo.patch.bz2 5028 BLAKE2B f8f809252d89b9195601953c6741c9a653b658d86669f149380dc94da91085921f58fef7e6f232cc421cf62f7321630120a85ec4dfdf369d6e92c0a7ae81e0f1 SHA512 bdae4fed6f8c61337e855235bf84b20faa363a3dfad9b2f22a017bd232aaf7f4bc0680f2b5567d6545ef3cb6ce7d41cc2287f4f0a2baf68ce3c56c68df8c77b8
DIST chkrootkit-0.55.tar.gz 42630 BLAKE2B 0e6bc4d411a7836cd8ab72782027e5bd80b5c8845d8de1f48ff57bc0617a368cff2471835a66c30d007f4cfc243639110e0c39e02eecc3ec9c5c0a66a4b7891b SHA512 742dca90a761ecff149d8704cb3a252adfe8f9d5e15dd060e9db4d5f6dcd3820933ae13cbee99ea5a8c6144932cf97c0616a177af3ba5a1726b51bb304e7d63e
DIST chkrootkit-0.57-gentoo.patch.bz2 5143 BLAKE2B 2b6018881b12121d6317f45d1b761a0b27e13bcfe4d936a468a13968357039419bb85650a4e0aa85f475226cd196fc17d3bac1222dc5be39f715c3d01a64b8a6 SHA512 21a389bfe1fc838cbf527db107ac7081ad61a90da04ab96d7a1bdd352f1e40745b0a5e31559fde7ff8f4214718510a281f9eb67de38df33f13b9ac2e3c640251
DIST chkrootkit-0.57.tar.gz 41948 BLAKE2B b75bec7e5f582aad363c84308c57de9881facf0176ef8c32adcdffdb04182f248b1dcc40b6df439bb9014580383b7f43e7503877098e8ecba6740c21b46b23a1 SHA512 ff35f01042bc68bdd10c4e26dbde7af7127768442c7a10f114260188dcc7e357e2c48d157c0b83b99e2fd465db3ed3933c84ae12fa411c5c28f64b955e742ff7

70
app-forensics/chkrootkit/chkrootkit-0.57.ebuild Normal file
View File

@@ -0,0 +1,70 @@
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit systemd toolchain-funcs
GENTOO_PATCH="${P}-gentoo.patch"
DESCRIPTION="Tool to locally check for signs of a rootkit"
HOMEPAGE="http://www.chkrootkit.org/"
SRC_URI="ftp://chkrootkit.org/pub/seg/pac/${P}.tar.gz"
SRC_URI+=" https://dev.gentoo.org/~tupone/distfiles/${CATEGORY}/${PN}/${GENTOO_PATCH}.bz2"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="+cron"
RDEPEND="cron? ( virtual/cron )"
PATCHES=(
"${WORKDIR}/${P}-gentoo.patch"
"${FILESDIR}/${PN}-0.55-fcntl_h.patch"
"${FILESDIR}/${PN}-0.55-limits_h.patch"
)
src_prepare() {
default
sed -e 's:/var/adm/:/var/log/:g' \
-i chklastlog.c || die
}
src_compile() {
emake CC="$(tc-getCC)" STRIP=/bin/true sense
}
src_install() {
dosbin chkdirs chklastlog chkproc chkrootkit chkwtmp chkutmp ifpromisc strings-static
dodoc ACKNOWLEDGMENTS README*
if use cron ; then
exeinto /etc/cron.weekly
newexe "${FILESDIR}"/${PN}.cron ${PN}
fi
systemd_dounit "${FILESDIR}/${PN}.timer" "${FILESDIR}/${PN}.service"
}
pkg_postinst() {
if use cron ; then
elog
elog "Edit ${EROOT}/etc/cron.weekly/chkrootkit to activate chkrootkit!"
elog
fi
if systemd_is_booted || has_version sys-apps/systemd ; then
elog
elog "To enable the systemd timer, run the following command:"
elog " systemctl enable --now chkrootkit.timer"
elog
fi
elog
elog "Some applications, such as portsentry, will cause chkrootkit"
elog "to produce false positives. Read the chkrootkit FAQ at"
elog "http://www.chkrootkit.org/ for more information."
elog
}