dev-python/astroid: Bump to 2.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/astroid/Manifest

@@ -1 +1,2 @@
 DIST astroid-2.4.2.tar.gz 310972 BLAKE2B 23ebe5ef418ce19b64eb1c0f8d711c3f0d86ae32cff112d9a99db48d20a34c73cfa97c96229fd0f0f1169720d24e2cfd0b5a327c29ea0fc0f54a57ede45fcebe SHA512 f5d759c07a13e06d3d071faacff2dc775924566aaef8bdb6e526c4ebf723b6b561f5824b711b33e33a2a69df0a2ff4cbf0f4302c9a0d55610e031e81c4a4be91
+DIST astroid-2.5.tar.gz 304788 BLAKE2B 3d9304dcfff72aa8172fe88b5ee53b723b47b3e602b7c30cae15a61d0cff7d578ccfde4885b56c09c8254ca3fe185fcf297bf85184d68798eb51f1860c516db6 SHA512 eba7e757a12f89a74bff579731a157fda3c8d8dd1b5a4369791d47f7f6e321b23e167260d0988d389428222c8c98929e66ad26f379ff937e274dcd1abdb3b3d2

dev-python/astroid/astroid-2.5.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="https://github.com/PyCQA/astroid https://pypi.org/project/astroid/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.11.2[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/astroid-2.4.2-no-pytest-runner.patch
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -r -e 's:"(wrapt|six|lazy_object_proxy)(~|=)=.+":"\1":' \
+		-i astroid/__pkginfo__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		# no clue why it's broken
+		--deselect
+		tests/unittest_modutils.py::GetModulePartTest::test_knownValues_get_builtin_module_part
+	)
+	[[ ${EPYTHON} == python3.9 ]] && deselect+=(
+		--deselect
+		tests/unittest_brain.py::TypingBrain::test_namedtuple_few_args
+		--deselect
+		tests/unittest_brain.py::TypingBrain::test_namedtuple_few_fields
+		--deselect
+		tests/unittest_brain.py::TypingBrain::test_namedtuple_inference_nonliteral
+		--deselect
+		tests/unittest_inference.py::test_dataclasses_subscript_inference_recursion_error
+	)
+
+	pytest -vv "${deselect[@]}" || die "Tests failed with ${EPYTHON}"
+}